pruio_gpio.bas

Go to the documentation of this file.

' PruIo global declarations.
#INCLUDE ONCE "pruio_globals.bi"
' Header for GPIO part.
#INCLUDE ONCE "pruio_gpio.bi"
' driver header file
#INCLUDE ONCE "pruio.bi"


CONSTRUCTOR GpioUdt(BYVAL T AS Pruio_ PTR)
  Top = T
  WITH *Top
    VAR i = .ParOffs
    InitParA = i
    i += 1 : .DRam[i] = &h44E07000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_GPIO0, &h44E00408uL, 0)

    i += 1 : .DRam[i] = &h4804C000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_GPIO1, &h44E000ACuL, 0)

    i += 1 : .DRam[i] = &h481AC000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_GPIO2, &h44E000B0uL, 0)

    i += 1 : .DRam[i] = &h481AE000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_GPIO3, &h44E000B4uL, 0)
    .ParOffs = i
  END WITH
END CONSTRUCTOR



FUNCTION GpioUdt.initialize CDECL() AS ZSTRING PTR
  WITH *Top
    VAR p_mem = .MOffs + .DRam[InitParA] _
      , p_raw = CAST(ANY PTR, .DRam) + PRUIO_DAT_GPIO

    FOR i AS LONG = 0 TO PRUIO_AZ_GPIO
      Raw(i) = p_raw
      p_raw += SIZEOF(GpioArr)

      Init(i) = p_mem
      Conf(i) = p_mem + .DSize

      WITH *Conf(i)
        IF .ClAd = 0 ORELSE .REVISION = 0 THEN _ '    subsystem disabled
                .DeAd = 0 : .ClVa = &h30000 : p_mem += 16 : _
                    Init(i)->DeAd = 0 : Init(i)->ClAd = 0 : CONTINUE FOR
        .ClVa = 2
        .CLEARDATAOUT = 0
        .SETDATAOUT = 0
      END WITH

      WITH *Init(i)
        .CLEARDATAOUT = 0
        .SETDATAOUT = 0
        var a = i * 32, e = a + 31
        FOR b AS INTEGER = 0 TO PRUIO_AZ_BALL
          var p = b - a
          SELECT CASE Top->BallGpio(b)
          CASE a TO e : if bit(.OE, p) then continue for ' input pin
            if BIT(.DATAOUT, p) then Top->BallInit[b] OR= &b10000000
          END SELECT
        NEXT
      END WITH

      p_mem += SIZEOF(GpioSet)
    NEXT
  END WITH : RETURN 0
END FUNCTION



FUNCTION GpioUdt.config CDECL( _
    BYVAL Ball AS UInt8 _
  , BYVAL Mo AS UInt8 = CAST(UInt8, PRUIO_GPIO_IN_0)) AS ZSTRING PTR
  WITH *Top
    BallCheck(" GPIO", .Errr)
    IF 7 <> (Mo AND &b111)                      THEN .Errr = E1 : RETURN .Errr ' no GPIO mode
    VAR r = .BallGpio(Ball) ' resulting GPIO (index and bit number)
    Mode = Mo XOR .BallConf[Ball]
    IF Mo <> PRUIO_PIN_RESET ANDALSO Mode = 0                THEN RETURN 0 ' nothing to config
    Indx = r SHR 5 : IF 2 <> Conf(Indx)->ClVa   THEN .Errr = E0 : RETURN .Errr ' GPIO subsystem not enabled
    IF Mode AND &b10100000 THEN ' change direction or value?
      Mode = Mo
      Mask = 1 SHL (r AND 31)
      setGpioSs()
    END IF                                                      : RETURN .setPin(Top, Ball, Mo)
  END WITH
END FUNCTION



SUB GpioUdt.setGpioSs()
  WITH *Conf(Indx)
    IF BIT(Mode, 5) THEN '          input Ball
      .OE OR= Mask
      .CLEARDATAOUT AND= NOT Mask
      .SETDATAOUT   AND= NOT Mask
    ELSE '                         output Ball
      .OE AND= NOT Mask
      IF BIT(Mode, 7) THEN '          set high
        .CLEARDATAOUT AND= NOT Mask
        .SETDATAOUT    OR= Mask
      ELSE '                           set low
        .CLEARDATAOUT  OR= Mask
        .SETDATAOUT   AND= NOT Mask
      END IF
    END IF
  END WITH
  WITH *Top
    IF .DRam[0] > PRUIO_MSG_IO_OK                          THEN EXIT SUB

    PruReady(1) ' wait, if PRU is busy (should never happen)
    .DRam[5] = Conf(Indx)->OE
    .DRam[4] = Conf(Indx)->SETDATAOUT
    .DRam[3] = Conf(Indx)->CLEARDATAOUT
    .DRam[2] = Conf(Indx)->DeAd + &h100
    .DRam[1] = PRUIO_COM_GPIO_CONF SHL 24
  END WITH
END SUB



FUNCTION GpioUdt.flush CDECL(BYVAL Indx AS UInt8) AS ZSTRING PTR
  WITH *Top
    IF 2 <> Conf(Indx)->ClVa                    THEN .Errr = E0 : RETURN .Errr ' GPIO subsystem not enabled
    IF .DRam[0] > PRUIO_MSG_IO_OK _
                          THEN .Errr = @"main loop not running" : RETURN .Errr

    PruReady(1) ' wait, if PRU is busy (should never happen)
    .DRam[5] = Conf(Indx)->OE
    .DRam[4] = Conf(Indx)->SETDATAOUT
    .DRam[3] = Conf(Indx)->CLEARDATAOUT
    .DRam[2] = Conf(Indx)->DeAd + &h100
    .DRam[1] = PRUIO_COM_GPIO_CONF SHL 24
  END WITH : RETURN 0
END FUNCTION



FUNCTION GpioUdt.setValue CDECL( _
    BYVAL Ball AS UInt8 _
  , BYVAL Mo AS UInt8 = 0) AS ZSTRING PTR

  WITH *Top
    BallCheck(" GPIO output", .Errr)
    VAR r = .BallGpio(Ball)  ' resulting GPIO (index and bit number)
    Indx = r SHR 5 : IF 2 <> Conf(Indx)->ClVa   THEN .Errr = E0 : RETURN .Errr ' GPIO subsystem not enabled
    Mask = 1 SHL (r AND 31)
    SELECT CASE AS CONST Mo
    CASE 0    : Mode = PRUIO_GPIO_OUT0 : r = .BallConf[Ball] XOR Mode
    CASE 1    : Mode = PRUIO_GPIO_OUT1 : r = .BallConf[Ball] XOR Mode
    CASE 255  : Mode = .BallInit[Ball] : r = Mo ' reset
    CASE ELSE : IF &b111 <> (Mo AND &b111)      THEN .Errr = E1 : RETURN .Errr ' no Gpio mode
                Mode = Mo              : r = .BallConf[Ball] XOR Mo
    END SELECT
    IF r AND &b10100000 THEN setGpioSs() ' i/o or state changed -> configure GPIO subsystem
    IF r AND &b01011000 THEN _ '         receiver or resistor changed -> pinmux
      IF .setPin(Top, Ball, Mode) THEN _ ' error -> re-conf and report error
                           Mode = .BallConf[Ball] : setGpioSs() : RETURN .Errr
    /' all OK, set new mode '/           .BallConf[Ball] = Mode : RETURN 0
  END WITH
END FUNCTION



FUNCTION GpioUdt.Value CDECL(BYVAL Ball AS UInt8) AS Int32
  WITH *Top
    BallCheck(" GPIO input", -1)
    VAR r = .BallGpio(Ball) _ ' resulting GPIO (index and bit number)
      , i = r SHR 5 _         ' index of GPIO
      , n = r AND 31          ' number of bit
    IF 2 <> Conf(i)->ClVa THEN                       .Errr = E0 : RETURN -1 ' GPIO subsystem not enabled
    IF &b111 <> (.BallConf[Ball] AND &b111) THEN     .Errr = E2 : RETURN -1 ' no GPIO pin
                                   RETURN IIF(BIT(Raw(i)->Mix, n), 1, 0)
  END WITH
END FUNCTION