disphelper
 
Disphelper является вспомогательной библиотекой COM, которую можно использовать в обычном языке C. MFC или ATL не требуется. Это позволяет вызывать СОМ-объекты с легким printf стилем синтаксиса.

Вебсайт: http://disphelper.sourceforge.net/
Поддерживаемые платформы: Win32, Linux (using WINE)
Заголовки: disphelper/disphelper.bi
Версия заголовков: от 2005

Пример

'' Пример HTTP GET, используя MSXML2

#define UNICODE
#include "disphelper/disphelper.bi"

DISPATCH_OBJ(objHTTP)

dhInitialize(TRUE)
dhToggleExceptions(TRUE)

dhCreateObject("MSXML2.XMLHTTP.4.0", NULL, @objHTTP)

dhCallMethod(objHTTP, ".Open(%s, %s, %b)", "GET", "http://sourceforge.net", FALSE)
dhCallMethod(objHTTP, ".Send")

Dim As ZString Ptr szResponse
dhGetValue("%s", @szResponse, objHTTP, ".ResponseText")

Print "Response: "; *szResponse
dhFreeString(szResponse)

SAFE_RELEASE(objHTTP)
dhUninitialize(TRUE)


'' Пример IExplorer

#define UNICODE
#include "disphelper/disphelper.bi"

Sub navigate(ByRef url As String)
    DISPATCH_OBJ(ieApp)
    dhInitialize(TRUE)
    dhToggleExceptions(TRUE)

    dhCreateObject("InternetExplorer.Application", NULL, @ieApp)
    dhPutValue(ieApp, "Visible = %b", TRUE)
    dhCallMethod(ieApp, ".Navigate(%s)", url)

    SAFE_RELEASE(ieApp)
    dhUninitialize(TRUE)
End Sub

    navigate("www.freebasic.net")


'' Пример VB Script

#define UNICODE
#include "disphelper/disphelper.bi"

'' Эта функция выполняет сценарий, используя MSScriptControl.
'' Опционально возвращает результат.
Sub RunScript _
    ( _
        ByVal result_identifier As LPWSTR, _
        ByVal result As LPVOID, _
        ByVal script As LPWSTR, _
        ByVal language As LPWSTR _
    )

    DISPATCH_OBJ(control)
    If (SUCCEEDED(dhCreateObject("MSScriptControl.ScriptControl", NULL, @control))) Then
        If (SUCCEEDED(dhPutValue(control, ".Language = %T", language))) Then
            dhPutValue(control, ".AllowUI = %b", TRUE)
            dhPutValue(control, ".UseSafeSubset = %b", FALSE)

            If (result) Then
                dhGetValue(result_identifier, result, control, ".Eval(%T)", script)
            Else
                dhCallMethod(control, ".Eval(%T)", script)
            End If
        End If
    End If

    SAFE_RELEASE(control)
End Sub

    dhInitialize(TRUE)
    dhToggleExceptions(TRUE)

    '' VBScript образец
    RunScript(NULL, NULL, !"MsgBox(\"This Is a VBScript test.\" & vbcrlf & \"It worked!\",64 Or 3)", "VBScript")

    '' JScript образец
    Dim As Integer result
    RunScript("%d", @result, "Math.round(Math.pow(5, 2) * Math.PI)", "JScript")
    Print "Result ="; result

    Print "Press any key to exit..."
    Sleep

    dhUninitialize(TRUE)