{ Type | Class | Union | Enum } typename

Declare Operator Let ( [ ByRef | ByVal ] rhs As datatype )

End { Type | Class | Union }

Operator typename.Let ( [ ByRef | ByVal ] rhs As datatype )

lhs = rhs

typename
lhs
rhs

Let используется для перегрузки Оператора = (Присваивание) и чтобы отличить его от оператора сравнения Оператор = (Равно).

lhs = rhs присвоит rhs в lhs , ссылаясь на процедуру оператора Let определенную typename.

Оператор Let (присваивание) должен быть определен, если неполная неявная копия не является достаточной. Это происходит в тех случаях, когда объект управляет динамически выделяемой памятью или другими ресурсами, которые должны быть специально скопированы (например, если указатель-элемент укажет на динамически-выделенную память, то неявный оператор присваивания просто скопирует значение указателя , вместо выделения памяти , а затем выполнит копию данных).

Type UDT
  Public:
    Declare Constructor (ByVal zp As Const ZString Ptr)  ''Конструктор со строковым инициализатором
    Declare Operator Let (ByRef rhs As UDT)              ''Оператор Let (присваивание)
    Declare Function getString () As String              ''Функция для получения строки
    Declare Destructor ()                                ''Деструктор
  Private:         
    Dim zp As ZString Ptr                                ''private указатель, чтобы избежать прямого доступа
End Type

Constructor UDT (ByVal zp As Const ZString Ptr)
  This.zp = CAllocate(Len(*zp) + 1)
  *This.zp = *zp
End Constructor

Operator UDT.Let (ByRef rhs As UDT)
  If @This <> @rhs Then  '' проверить для того, чтобы избежать разрушения объекта
    Deallocate(This.zp)
    This.zp = CAllocate(Len(*rhs.zp) + 1)
    *This.zp = *rhs.zp
  End If
End Operator

Function UDT.getString () As String
  Return *This.zp
End Function

Destructor UDT ()
  Deallocate(This.zp)
End Destructor


Dim u As UDT = UDT("")
u = Type<UDT>("Thanks to the overloading operator Let (assign)")
Print u.getString
Sleep

Вывод:

Thanks to the overloading operator Let (assign)

• В диалектах -lang qb и -lang fblite, этот оператор не может быть перегружен.
  
• В диалектах -lang qb и -lang fblite , выражение присваивания может предшествовать ключевому слову Let.
  
  

• Нет
  
  

• Let
  
• Оператор Let() (Присваивание)
  
• Оператор = (Присваивание)
  
• Оператор = (Равно)