Изучение языка программирования означает изучение ключевых слов, чтобы хоть что-то написать , понимать как эти ключевые слова работают и вообще для чего они. Нам не нужно изучать их всех сразу, для начала хватит изучить несколько ключевых слов. Здесь мы просто собираемся сконцентрироваться на этих ключевых словах:

• Dim
  
• Print
  
• Input
  
• For...Next
  
• If...Then
  
• Do...Loop
  
  
  

Ни одно руководство для начинающих не обходится без этого примера.

Print "Hello World!"

Текст между парой двойных кавычек является строковым литералом. Оператор Print используется для вывода текста на экран. Если вы можете редактировать, компилировать и выполнять этот пример, вы находитесь на правильном пути.

Иногда в программе мы хотим хранить некоторую информацию в памяти и затем использовать её в дальнейшем. Для хранения чего-то в памяти мы используем переменную. Все переменные в FreeBASIC имеют определенный тип, как число или строка. Мы используем оператор Dim для объявления имени переменной и указываем, какого она типа.

Dim text As String
text = "Hello World!"
Print text

Мы используем Dim, чтобы компилятор знал, что мы хотим использовать переменную с именем text в нашей программе и согласно типу string , мы будем держать в ней строковые данные. Затем мы присваиваем(копируем) строку «Hello World!» в переменную. Наконец мы используем Print для вывода значения переменной на экран.

Выражение - это общий термин для описания части исходного кода, которое может быть оценено. После того, как вычисляется выражение, мы можем сделать что-то с ним, например присвоить(копировать) его в переменную.

Dim a As String, b As String, text As String
a = "Hello"
b = "World"
text = a + " " + b + "!"
Print text

Мы присваиваем переменным a и b некоторые данные. Затем мы используем переменные a и b в выражении, которое потом присваиваем переменной text. Наконец, мы выводим результат на экран.

Часто, мы понятия не имеем, какие данные необходимы для программы, пока пользователь не даст их нам. Мы не можем их поместить в наш исходный код, так как эти данные получаются от пользователя во время выполнения программы.

Dim answer As String
Input "Type something and press enter:", answer
Print "You typed: '"; answer; "'"

Оператор Input сначала выводит некоторую информацию , а затем будет ожидать ввода данных от пользователя, чтобы затем поместить эти данные в нашу программу. В этом примере мы просто выводим на экран то, что ввел пользователь.

Переменные и выражения не ограничиваются строками. Большинство ранних языков плохо обрабатывали строки, если вообще обрабатывали. Написание математических выражений аналогично тому, как они могут быть написаны с помощью карандаша и бумаги.

Dim a As Integer, b As Integer, c As Integer

a = 5
b = 7
c = a + b

Print "a = "; a
Print "a = "; b
Print "a + b = "; c

Мы присваиваем значения переменным a, b и c. Мы используем тип Integer для данных переменных. Целое число может быть положительным или отрицательным, но оно не может иметь дробной части.

Это подобно предыдущему примеру, но дополнительно мы позволям пользователю выбирать числа, которые мы собираемся складывать.

Dim a As Integer, b As Integer, r As Integer
Input "Enter a number:", a
Input "Enter another number:", b

r = a + b
Print "The sum of the numbers is "; r

Dim позволяет компилятору знать, какие имена переменных мы хотим использовать и что они будут с типом Integer. Мы используем Input, чтобы получить числа от пользователя и Print , чтобы вывести результат на экран.

Числовые переменные не ограничены целыми числами. Мы также можем использовать типы Single или Double для большей точности (эти типы могут работать с дробными чисами). В этом примере мы получим некоторые данные от пользователя, чтобы преобразовать вес в фунтах к весу в килограммах.

Dim lb As Single, kg As Single
Input "Enter a weight in pounds:", lb

kg = lb * 0.454
Print lb; " lb. is equal to "; kg; " kg"

Используя оператор For...Next , мы можем указать программе выполнять какую-то операцию определенное количество раз. Например , мы можем сложить все числа от 1 до 100.

Dim total As Integer
Dim number As Integer
total = 0
For number = 1 To 100
  total = total + number
Next
Print "The sum of number from 1 to 100 is "; total

Программа может выбрать, какие операции выполнять, используя условный оператор, как If...Then. Мы можем использовать значение переменной или результат выражения, которое будет влиять на решение какие операции должны выполняться, а какие нет.

Dim number As Integer
Input "Enter a number : ", number
Print "Your number is ";
If number < 0 Then
  Print "negative"
ElseIf number > 0 Then
  Print "positive"
Else
  Print "zero"
End If

После получения числа от пользователя, мы собираемся вывести слово (положительное, отрицательное или нулевое), на основе того, какое число ввел пользователь.

Здесь мы будем использовать другую структуру циклов Do...Loop для повторения некоторых операций. Как программа будет знать, когда перестать повторять операции? Мы будем использовать If...Then, для принятия решения, когда выйти из цикла.

Dim total As Single, count As Single, number As Single
Dim text As String

Print "This program will calculate the sum and average for a"
Print "list of numbers.  Enter an empty value to end."
Print

Do
  Input "Enter a number : ", text
  If text = "" Then
    Exit Do
  End If

  count = count + 1
  total = total + Val(text)

Loop

Print
Print "You entered "; count; " numbers"
Print "The sum is "; total
If count <> 0 Then
  Print "The average is "; total / count
End If

• Dim
  
• Print
  
• Input
  
• For...Next
  
• If...Then
  
• Do...Loop