SCREEN (Funktion)

FreeBASIC-Referenz » Alphabetische Befehlsreferenz » S » SCREEN (Funktion)

Syntax: SCREEN (Zeile, Spalte [, Typ])
Typ: Funktion
Kategorie: Konsole

SCREEN gibt Informationen über den Text im Konsole- oder Grafik-Fenster zurück.

Beispiel:

DIM i AS INTEGER
WIDTH 80, 25

FOR i = 1 TO 16
COLOR i, (i + 8) MOD 16
PRINT "1234567890"
NEXT

COLOR 15, 0
LOCATE 1, 20
PRINT "ASCII-Code in Zeile 5, Spalte 7:"
LOCATE 2, 20
PRINT SCREEN(5, 7, 0)

LOCATE 4, 20
PRINT "Vordergrundfarbe in Zeile 2, Spalte 10:"
LOCATE 5, 20
PRINT (SCREEN(2, 10, 1)) MOD 16

LOCATE 7, 20
PRINT "Hintergrundfarbe in Zeile 7, Spalte 5:"
LOCATE 8, 20
PRINT (SCREEN(7, 5, 1)) \ 16

SLEEP

Unterschiede zu QB:
In QB erzeugt SCREEN einen Fehler, wenn Koordinaten außerhalb des Fensters verwendet werden.

Plattformbedingte Unterschiede:
Unter Linux kann der zurückgegebene Wert vom in der Konsole angezeigten Wert abweichen. Zum Beispiel können nicht anzeigbare Kontrollcodes wie das LF-Zeichen (ASCII-Zeichen 10), welches das Ende des geschriebenen Textes markiert, übernommen werden.

Siehe auch:
SCREEN (Anweisung), LOCATE, COLOR (Anweisung), WIDTH (Anweisung), PRINT (Anweisung)