fbdoc_emit_gtk.bas

Go to the documentation of this file.

#INCLUDE ONCE "fbdoc_options.bi"
#INCLUDE ONCE "fbdoc_version.bi"


CONST _
      SINCE = NL & "Since: 0.0", _ 
  GTK_START =           "/'* ", _       
    GTK_END = NL & _
              NL & TOFIX & _
              NL & SINCE & _
              NL & COMM_END             



SUB gtk_emit_Name CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    IF .NamTok THEN Code(NL & "@" & P->SubStr(P->NamTok) & ": " & TOFIX)
  END WITH
END SUB



SUB gtk_defi_ CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    emit_source(P, .StaTok[1])
    Code(GTK_START & .SubStr(.NamTok) & ":" & GTK_END)
  END WITH
END SUB



SUB gtk_decl_ CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    IF 0 = .ListCount THEN
      emit_source(P, .Tk1[1])
      Code(GTK_START & .SubStr(.NamTok) & ":")
    END IF

    IF 0 = .FunTok THEN gtk_emit_Name(P) _
                   ELSE IF .ParTok THEN .parseListPara(@gtk_emit_Name())

    IF *.CurTok > .TOK_EOS THEN EXIT SUB
    Code(GTK_END)

    IF 0 = .FunTok THEN EXIT SUB
    Code("'' " & PROJ_NAME & "-hint: consider to document the functions body instead." & NL)
  END WITH
END SUB



SUB gtk_func_ CDECL(BYVAL P AS Parser PTR) ' !!! ToDo member functions
  WITH *P '&Parser* P;
    VAR t = .TypTok
    emit_source(P, .StaTok[1])
    Code(GTK_START & .SubStr(.NamTok) & ":")
    IF .ParTok THEN .parseListPara(@gtk_emit_Name())

    Code( _
        NL & _
        NL & TOFIX)
    IF t THEN Code( _
        NL & _
        NL & "Returns: " & TOFIX)
    Code(    SINCE & _
        NL & COMM_END)
  END WITH
END SUB



SUB gtk_emitBlockNames CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    SELECT CASE AS CONST *.Tk1
    CASE .TOK_PRIV, .TOK_PROT ': .SrcBgn = 0 ' !!! ToDo: hide private?
    CASE .TOK_PUBL            ': .SrcBgn = 1
    CASE .TOK_CLAS, .TOK_TYPE, .TOK_UNIO
      .parseBlockTyUn(@gtk_emitBlockNames())
    CASE .TOK_ENUM
      .parseBlockEnum(@gtk_emit_Name())
    CASE ELSE : IF 0 = .NamTok THEN EXIT SUB
      gtk_emit_Name(P)
    END SELECT
  END WITH
END SUB



SUB gtk_Block CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    emit_source(P, .StaTok[1])
    Code( GTK_START)
    IF LEN(.BlockNam) THEN Code(.BlockNam & ":")

    SELECT CASE AS CONST *.Tk1
    CASE .TOK_ENUM : .parseBlockEnum(@gtk_emit_Name())
    CASE ELSE :      .parseBlockTyUn(@gtk_emitBlockNames())
    END SELECT

    Code(GTK_END)
  END WITH
END SUB



SUB gtk_empty CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    Code(  GTK_START & _
           "SECTION: " & TOFIX & _
      NL & "@short_description: " & TOFIX & _
      NL & "@title: " & TOFIX & _
      NL & "@section_id: " & TOFIX & _
      NL & "@see_also: " & TOFIX & _
      NL & "@stability: " & TOFIX & _
      NL & "@include: " & TOFIX & _
      NL & "@image: " & TOFIX & _
           GTK_END & _
      NL)
  END WITH
END SUB




SUB init_gtk(BYVAL Emi AS EmitterIF PTR)
  WITH *Emi
    .Error_ = @emit_error()  

     .Func_ = @gtk_func_()
     .Decl_ = @gtk_decl_()
     .Defi_ = @gtk_defi_()
     .Enum_ = @gtk_Block()
     .Unio_ = @gtk_Block()
     .Clas_ = @gtk_Block()
     .Init_ = @geany_init()
     .Exit_ = @geany_exit()
    .Empty_ = @gtk_empty()
  END WITH
END SUB