fbdoc_emitters.bas

Go to the documentation of this file.

#INCLUDE ONCE "fbdoc_options.bi"
#INCLUDE ONCE "fbdoc_version.bi"



SUB emit_comments CDECL(BYVAL P AS Parser PTR, BYVAL Stop_ AS INTEGER)
  WITH *P '&Parser* P;
    VAR i = .SrcBgn
    WHILE i <= Stop_
      SELECT CASE AS CONST .Buf[i]
      CASE 0 : EXIT WHILE
      CASE ASC(!"\n") : Code(NL)
      CASE ASC("""")
        SCAN_QUOTE(.Buf,i)
      CASE ASC("'")
        VAR c = i + 1
        SCAN_SL_COMM(.Buf,i)
        IF .Buf[c] = OPT->JoComm THEN c += 1 : Code("//!" & MID(.Buf, c + 1, i - c))
        IF .Buf[c] = OPT->AdLine THEN c += 1 : Code(MID(.Buf, c + 1, i - c))
        CONTINUE WHILE
      CASE ASC("/") : IF .Buf[i + 1] <> ASC("'") THEN EXIT SELECT
        i += 2
        VAR c = IIF(.Buf[i] = OPT->JoComm, i + 1, 0)
        IF c THEN Code("/*!")
        DO
          SELECT CASE AS CONST .Buf[i]
          CASE 0 : EXIT DO
          CASE ASC(!"\n") : IF 0 = c THEN Code(NL) : EXIT SELECT
            Code(MID(.Buf, c + 1, i - c + 1))
            c = i + 1
            IF OPT->Asterix THEN Code("* ")
          CASE ASC("'")
            SELECT CASE AS CONST .Buf[i + 1]
            CASE 0 : EXIT SUB
            CASE ASC("/") : i += 1 : EXIT DO
            END SELECT
          END SELECT : i += 1
        LOOP
        IF c THEN Code(MID(.Buf, c + 1, i - c - 1) & "*/")
      END SELECT : i += 1
    WEND : IF .SrcBgn < i THEN .SrcBgn = i
  END WITH
END SUB



SUB cppNam CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    VAR t = .NamTok
    Code(.SubStr(t))
    WHILE t < .EndTok
      t += 3
      SELECT CASE AS CONST *t
      CASE  .TOK_DOT : Code("::")
      CASE .TOK_WORD : Code(.SubStr(t))
      CASE ELSE : EXIT WHILE
      END SELECT
    WEND
  END WITH
END SUB



SUB cNam CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    FOR i AS INTEGER = 1 TO .PtrCount : Code("*") : NEXT
    VAR t = .NamTok, a = t[1], l = t[2]
    WHILE t < .EndTok
      t += 3
      SELECT CASE AS CONST *t
      CASE .TOK_DOT, .TOK_WORD : l += t[2]
      CASE ELSE : EXIT WHILE
      END SELECT
    WEND : Code(MID(.Buf, a + 1, l))
  END WITH
END SUB



SUB CreateIni CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    VAR kl = 0, i = .IniTok[1], a = i, e = 0, atc = 0
    Code(" ")
    DO
      i += 1
      SELECT CASE AS CONST .Buf[i]
      CASE 0 : EXIT DO
      CASE ASC(!"\n")
        Code(MID(.Buf, a + 1, IIF(e, e, i) - a))
        a = i + 1
        IF kl <= 0 ANDALSO (e = 0 ORELSE .Buf[e] <> ASC("_")) THEN EXIT SUB
        emit_comments(P, i)
        e = 0
      CASE ASC("@")
        IF kl <= 0 THEN atc = i
      CASE ASC("_")
        IF .Buf[i + 1] < ASC("0") ANDALSO .Buf[i - 1] < ASC("0") THEN e = IIF(e, e, i)
      CASE ASC("'")
        e = IIF(e, e, i)
      CASE ASC("/")
        IF .Buf[i + 1] = ASC("'") THEN e = IIF(e, e, i)
      CASE ASC("""")
        VAR esc = IIF(.Buf[i - 1] = ASC("!"), 1, 0)
        IF atc THEN .Buf[atc] = ASC(" ")
        DO
          i += 1
          SELECT CASE AS CONST .Buf[i]
          CASE 0, ASC(!"\n") : i -= 1 : EXIT DO
          CASE ASC("\") : IF esc THEN i += 1
          CASE ASC("""") : IF .Buf[i + 1] = ASC("""") THEN i += 1 ELSE EXIT DO
          END SELECT
        LOOP
      CASE ASC("("), ASC("{"), ASC("[") : kl += 1
      CASE ASC(")"), ASC("}"), ASC("]") : kl -= 1 : IF kl <  0 THEN EXIT DO
      CASE ASC(",")                               : IF kl <= 0 THEN EXIT DO
      END SELECT
    LOOP UNTIL i >= .EndTok[1] : IF i <= a THEN EXIT SUB
    Code(MID(.Buf, a + 1, IIF(e, e, i) - a))
    IF atc THEN .Buf[atc] = ASC("@")
  END WITH
END SUB



SUB cArrDim CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    VAR t = .DimTok, kl = 0
    DO
      SELECT CASE AS CONST *t
      CASE .TOK_COMMA
        SELECT CASE AS CONST t[-3]
        CASE .TOK_3DOT, .TOK_ANY : Code("][")
        CASE ELSE :                Code(" + 1][")
        END SELECT
      CASE .TOK_BROPN : kl += 1 : Code("[")
        IF t[3] = .TOK_COMMA ORELSE t[3] = .TOK_BRCLO THEN _
          Code(MID(.Buf, t[1] + 2, t[4] - t[1] - 1))
      CASE .TOK_BRCLO : kl -= 1
        SELECT CASE AS CONST t[-3]
        CASE .TOK_3DOT, .TOK_ANY : Code("]")
        CASE ELSE :                Code(" + 1]")
        END SELECT
        IF kl <= 0 THEN EXIT DO
      CASE ELSE                 : Code(.SubStr(t))
      END SELECT : t += 3
    LOOP UNTIL t >= .EndTok
  END WITH
END SUB



SUB cppCreateTypNam CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    IF .TypTok THEN
      IF .ShaTok THEN Code(.SubStr(.ShaTok) & "_")
      IF .Co1Tok THEN Code(.SubStr(.Co1Tok) & "_")
                      Code(.SubStr(.TypTok))
      IF .Co2Tok THEN Code("_" & .SubStr(.Co2Tok))
      FOR i AS INTEGER = 1 TO .PtrCount
                      Code("_" & .SubStr(.PtrTok)) : NEXT
      IF .NamTok THEN Code(" ") ELSE EXIT SUB
    ELSE
      Code(" ")
    END IF

    IF .NamTok > .TypTok _
      THEN emit_comments(P, .NamTok[1])

    IF .NamTok THEN   cppNam(P)
    IF .DimTok THEN   cArrDim(P)
    IF .BitTok THEN   Code(.BitIni)
    IF .IniTok THEN   CreateIni(P)
  END WITH
END SUB



SUB cCreateTypNam CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    IF .TypTok THEN
      IF .Co1Tok THEN             Code("const ")

      SELECT CASE AS CONST *.TypTok
      CASE            .TOK_BYTE : Code("signed char")
      CASE            .TOK_UBYT : Code("unsigned char")
      CASE            .TOK_SHOR : Code("short")
      CASE            .TOK_USHO : Code("unsigned short")
      CASE            .TOK_STRI : Code("char*") ' ??? FB_STRING, g_string
      CASE            .TOK_SING : Code("float")
      CASE            .TOK_DOUB : Code("double")
      CASE            .TOK_ZSTR : Code("char")
      CASE            .TOK_WSTR : Code("wchar")
      CASE .TOK_INT,  .TOK_LONG : Code("int")
      CASE .TOK_UINT, .TOK_ULNG : Code("unsigned int")
      CASE            .TOK_LINT : Code("LONG int")
      CASE            .TOK_ULIN : Code("unsigned LONG int")
      CASE ELSE                 : Code(.SubStr(.TypTok))
      END SELECT

      IF .Co2Tok THEN             Code(" " & .SubStr(.Co2Tok))
      IF .By_Tok ANDALSO *.By_Tok = .TOK_BYRE THEN .PtrCount += 1
      IF .NamTok THEN Code(" ") ELSE EXIT SUB
    END IF

    IF .NamTok > .TypTok _
      THEN emit_comments(P, .NamTok[1])

    SELECT CASE AS CONST *.StaTok
    CASE .TOK_TYPE, .TOK_DIM, .TOK_RDIM, .TOK_COMM, .TOK_EXRN
      IF .FunTok THEN Code("(") : cNam(P) : Code(")") : EXIT SUB
    END SELECT
    IF .NamTok THEN cNam(P)
    IF .BitTok THEN Code(.BitIni)
    IF .DimTok THEN cArrDim(P) ': Code()
    IF .IniTok THEN CreateIni(P)
  END WITH
END SUB



SUB cppEntryListParameter CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    emit_comments(P, .Tk1[1])

    IF .FunTok THEN
      IF .By_Tok THEN Code(.SubStr(.By_Tok) & "_")
      IF .DivTok THEN Code("_" & .SubStr(.DivTok))
      cppCreateFunction(P)
    ELSEIF .TypTok THEN
      IF .By_Tok THEN Code(.SubStr(.By_Tok) & "_")
      Code(.SubStr(.As_Tok) & "_")
      cppCreateTypNam(P)
    ELSEIF *.NamTok = .TOK_3DOT THEN
      Code("...)") : EXIT SUB
    END IF

    IF *.CurTok <> .TOK_BRCLO      THEN Code(", ") : EXIT SUB
    emit_comments(P, .CurTok[1]) : Code(")")
  END WITH
END SUB



SUB cEntryListParameter CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    emit_comments(P, .Tk1[1])

    IF .FunTok THEN
      cCreateFunction(P)
    ELSEIF .TypTok THEN
      cCreateTypNam(P)
    ELSEIF .NamTok = .TOK_3DOT THEN
      Code("...")
    ELSE
      Code("void")
    END IF

    IF *.CurTok <> .TOK_BRCLO      THEN Code(", ") : EXIT SUB
    emit_comments(P, .CurTok[1]) : Code(")")
  END WITH
END SUB



SUB cppCreateFunction CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    'IF .DivTok THEN Code(.SubStr(.DivTok) & " ")
    IF .DivTok THEN Code(LCASE(.SubStr(.DivTok)) & " ")

    SELECT CASE AS CONST *.FunTok
    CASE .TOK_CTOR
      IF .NamTok THEN Code(.SubStr(.NamTok) & "::" & .SubStr(.NamTok)) ELSE _
                      Code(.BlockNam)
    CASE .TOK_DTOR
      IF .NamTok THEN Code(.SubStr(.NamTok) & "::~" & .SubStr(.NamTok)) ELSE _
                      Code("~" & .BlockNam)
    CASE ELSE
                      Code(.SubStr(.FunTok))
      IF .CalTok THEN Code("_" & .SubStr(.CalTok))
      IF .AliTok THEN Code("_" & .SubStr(.AliTok))
      IF .TypTok ANDALSO .As_Tok THEN _
                      Code("_" & .SubStr(.As_Tok) & "_")
      cppCreateTypNam(P)
    END SELECT : IF 0 = .ParTok THEN Code("(void)") : EXIT SUB

    emit_comments(P, .ParTok[1])
    Code(" (")
    .parseListPara(@cppEntryListParameter())
    IF .ListCount <= 0 THEN Code(")")
  END WITH
END SUB



SUB cCreateFunction CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    IF .DivTok THEN Code(.SubStr(.DivTok) & " ")

    SELECT CASE AS CONST *.FunTok
    CASE .TOK_CTOR
      Code(.SubStr(.FunTok) & " ")
      IF .NamTok THEN Code(.SubStr(.NamTok) & "." & .SubStr(.NamTok)) _
                 ELSE Code(.BlockNam)
    CASE .TOK_DTOR
      Code(.SubStr(.FunTok) & " ")
      IF .NamTok THEN Code(.SubStr(.NamTok) & "." & .SubStr(.NamTok)) _
                 ELSE Code(.BlockNam)
    CASE ELSE
      IF 0 = .TypTok THEN Code("void ")
      cCreateTypNam(P)
    END SELECT : IF 0 = .ParTok THEN Code("(void)") : EXIT SUB

    emit_comments(P, .ParTok[1])
    Code(" (")
    .parseListPara(@cEntryListParameter())
    IF .ListCount <= 0 THEN Code("void)")
  END WITH
END SUB



SUB emit_error CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    SELECT CASE AS CONST OPT->RunMode
    CASE OPT->GEANY_MODE ': EXIT SUB ' or shall we output?
      Code(NL & "'!!! " & PROJ_NAME & .ErrMsg & "!" & NL)
    CASE ELSE
      ERROUT("==> " & PROJ_NAME & .ErrMsg & "!")
    END SELECT
  END WITH
END SUB



SUB emit_source CDECL(BYVAL P AS Parser PTR, BYVAL E AS INTEGER)
  WITH *P '&Parser* P;
    DO : IF E > 0 THEN E -= 1 ELSE EXIT SUB
    LOOP UNTIL .Buf[E] = ASC(!"\n")
    VAR a = .SrcBgn, l = E - a : .SrcBgn = E + 1
    Code(MID(.Buf, a + 1, l + 1))
  END WITH
END SUB



SUB geany_init CDECL(BYVAL P AS Parser PTR)
  P->SrcBgn = 0
END SUB



SUB geany_exit CDECL(BYVAL P AS Parser PTR)
  WITH *P '&Parser* P;
    Code(MID(.Buf, .SrcBgn + 1))
  END WITH
END SUB


'/'* \brief Emitter with no action, to initialize the interface
'\param P the parser calling this handler '/
'SUB null_emitter CDECL(BYVAL P AS Parser PTR) : END SUB