shortcuts.bas

Go to the documentation of this file.

#DEFINE ACCELL_FILE "dat/accelerators.rc"





SUB populateShortcuts CDECL(BYVAL Act AS gpointer, BYVAL Store AS gpointer)

  STATIC AS GtkTreeIter iter

  STATIC AS GtkAccelKey acck



  VAR action = GTK_ACTION(Act)

  VAR accel_path = gtk_action_get_accel_path(action)



  IF 0 = accel_path THEN                                        EXIT SUB

  IF 0 = gtk_accel_map_lookup_entry(accel_path, @acck) _

    THEN gtk_accel_map_add_entry(accel_path, 0, 0)



  gtk_list_store_append(Store, @iter)

  gtk_list_store_set(Store, @iter _

    , 0, acck.accel_key _

    , 1, acck.accel_mods _

    , 2, gtk_action_get_label(action) _ '       don't free this and next

    , 3, gtk_action_get_tooltip(action) _

    , 4, accel_path _

    , -1) '                                    parameter list terminator

END SUB







FUNCTION evaluateShortcuts CDECL( _

  BYVAL Tree AS GtkTreeModel PTR _

, BYVAL Path AS GtkTreePath PTR _

, BYVAL Iter AS GtkTreeIter PTR _

, BYVAL user_data AS gpointer) AS gboolean



  DIM AS gpointer accel_path

  DIM AS guint accel_key, accel_mods

  gtk_tree_model_get(Tree, Iter _

    , 0, @accel_key _

    , 1, @accel_mods _

    , 4, @accel_path _

    , -1) '                                    parameter list terminator

  gtk_accel_map_change_entry(accel_path, accel_key, accel_mods, TRUE)



  RETURN FALSE

END FUNCTION







SUB ShortcutsForm(BYVAL Mo AS gint = 1)

  STATIC AS GtkListStore PTR store

  STATIC AS GObject PTR actgrp



  IF 0 = store THEN

    VAR xml = GUI.XML '         initial get objects from GUI description

      store = GTK_LIST_STORE(gtk_builder_get_object(xml, "liststore600"))

     actgrp = gtk_builder_get_object(xml, "actiongroup1")

  END IF



  SELECT CASE AS CONST Mo

  CASE 0 '                                          evaluate from dialog

    gtk_tree_model_foreach(GTK_TREE_MODEL(store), @evaluateShortcuts, NULL)

    gtk_accel_map_save(ACCELL_FILE)

  CASE ELSE '                                        populate the dialog

    gtk_accel_map_load(ACCELL_FILE)

    gtk_list_store_clear(store)

    VAR list = gtk_action_group_list_actions(GTK_ACTION_GROUP(actgrp))

    g_list_foreach(list, @populateShortcuts, store)

    g_list_free(list)

  END SELECT

END SUB







SUB act_Shortcut CDECL ALIAS "act_Shortcut" ( _

  BYVAL Action AS GtkAction PTR, _

  BYVAL Dialog AS gpointer) EXPORT



?" --> callback act_Shortcut"



  SELECT CASE AS CONST gtk_dialog_run(Dialog)

    CASE 0

?" --> callback act_Shortcut -> get changed settings"

      ShortcutsForm(0) ' load from form

    CASE ELSE

?" --> callback act_Shortcut -> dialog canceled, restore form"

      ShortcutsForm(1) ' restore form, because user canceled

  END SELECT

  gtk_widget_hide(Dialog)



END SUB







SUB on_accel_cleared CDECL ALIAS "on_accel_cleared" ( _

  BYVAL Accel AS GtkCellRendererAccel PTR, _

  BYVAL PathString AS gchar PTR, _

  BYVAL Store AS gpointer) EXPORT



  DIM AS GtkTreeIter iter

  VAR model = GTK_TREE_MODEL(Store)

  gtk_tree_model_get_iter_from_string(model, @iter, PathString)

  gtk_list_store_set(Store, @iter _

    , 0, CAST(guint, 0) _

    , 1, CAST(guint, 0) _

    , -1) '                                    parameter list terminator



END SUB







SUB on_accel_edited CDECL ALIAS "on_accel_edited" ( _

    BYVAL Accel AS GtkCellRendererAccel PTR _

  , BYVAL PathString AS gchar PTR _

  , BYVAL AccelKey AS guint _

  , BYVAL AccelMods AS GdkModifierType _

  , BYVAL HardwareKeycode AS guint _

  , BYVAL Store AS gpointer) EXPORT



  VAR model = GTK_TREE_MODEL(Store)



  DIM AS guint k, m

  DIM AS GtkTreeIter search

  IF gtk_tree_model_get_iter_first(model, @search) THEN

    DO

      gtk_tree_model_get(model, @search, 0, @k, 1, @m, -1)

      IF k <> AccelKey ORELSE m <> AccelMods THEN            CONTINUE DO



      DIM AS gchar PTR txt

      gtk_tree_model_get(model, @search, 2, @txt, -1)

      VAR dia = gtk_message_dialog_new_with_markup(GTK_WINDOW(GUI.window1) _

        , GTK_DIALOG_MODAL OR GTK_DIALOG_DESTROY_WITH_PARENT _

        , GTK_MESSAGE_QUESTION _

        , GTK_BUTTONS_YES_NO _

        , ( _

          *__(!"Shortcut already defined for\n\n") _

        & *__(!"<b>%s</b>\n\n") _

        & *__(!"Override existing\n") _

        ) _

        , txt _

        , NULL)

      g_free(txt)



      VAR r = gtk_dialog_run(GTK_DIALOG(dia))

      gtk_widget_destroy(dia) : IF r <> GTK_RESPONSE_YES THEN   EXIT SUB

      gtk_list_store_set(Store, @search _

        , 0, CAST(guint, 0) _

        , 1, CAST(guint, 0) _

        , -1) :                                                  EXIT DO

    LOOP UNTIL 0 = gtk_tree_model_iter_next(model, @search)

  END IF



  IF 0 = AccelMods THEN '                          shall we use this ???

    VAR dia = gtk_message_dialog_new_with_markup(GTK_WINDOW(GUI.window1) _

      , GTK_DIALOG_MODAL OR GTK_DIALOG_DESTROY_WITH_PARENT _

      , GTK_MESSAGE_QUESTION _

      , GTK_BUTTONS_YES_NO _

      , ( _

        *__(!"Shortcut has no modifier\n\n") _

      & *__(!"This interferes with the search\n") _

      & *__(!"function in the tree views\n\n") _

      & *__(!"Anyway, use it ...") _

      ) _

      , NULL)



    VAR r = gtk_dialog_run(GTK_DIALOG(dia))

    gtk_widget_destroy(dia) : IF r <> GTK_RESPONSE_YES THEN     EXIT SUB

  END IF



  DIM AS GtkTreeIter iter

  gtk_tree_model_get_iter_from_string(model, @iter, PathString)

  gtk_list_store_set(Store, @iter _

    , 0, AccelKey _

    , 1, AccelMods _

    , -1)

END SUB





' Here we initialize the dialog context (before starting the main window)

ShortcutsForm()