io_input.bas

Go to the documentation of this file.

' include libpruio
#INCLUDE ONCE "BBB/pruio.bi"


' *****  main  *****

VAR io = NEW PruIo 

WITH *io
  DO '                                  pseudo loop, just to avoid GOTOs
    IF .Errr THEN    ?"initialisation failed (" & *.Errr & ")" : EXIT DO

'                  transfer default settings to PRU and start in IO mode
    IF .config() THEN        ?"config failed (" & *.Errr & ")" : EXIT DO

    ?"   .   |   .   |   .   |   .   |"
    ?:?:?:?:?
    VAR x = POS() _      
      , y = CSRLIN() - 5 
    DO '                           print current state (until keystroke)
      LOCATE y, x, 0
      ?BIN(.Gpio->Raw(0)->Mix, 32) '                              GPIOs 0 - 3
      ?BIN(.Gpio->Raw(1)->Mix, 32)
      ?BIN(.Gpio->Raw(2)->Mix, 32)
      ?BIN(.Gpio->Raw(3)->Mix, 32)
      ?HEX(.Adc->Value[1], 4) & " " & _ '                           AIN 0 - 7
       HEX(.Adc->Value[2], 4) & " " & _
       HEX(.Adc->Value[3], 4) & " " & _
       HEX(.Adc->Value[4], 4) & "  " & _
       HEX(.Adc->Value[5], 4) & " " & _
       HEX(.Adc->Value[6], 4) & " " & _
       HEX(.Adc->Value[7], 4) & " " & _
       HEX(.Adc->Value[8], 4);
    LOOP UNTIL LEN(INKEY())
    ?
  LOOP UNTIL 1
END WITH

DELETE io '                    reset ADC, PinMux and GPIOs, clear memory

'' help Doxygen to document the main code
'&/** The main function. */
'&int main() {PruIo::PruIo(); PruIo::config(); PruIo::~PruIo();}