pruio_adc.bas

Go to the documentation of this file.

' PruIo global declarations.
#INCLUDE ONCE "pruio_globals.bi"

' Header for ADC part.
#INCLUDE ONCE "pruio_adc.bi"
' Header for GPIO part.
#INCLUDE ONCE "pruio_gpio.bi"
' driver header file
#INCLUDE ONCE "pruio.bi"


CONSTRUCTOR AdcUdt(BYVAL T AS Pruio_ PTR)
  Top = T
  WITH *Top
    VAR i = .ParOffs
    InitParA = i
    i += 1 : .DRam[i] = &h44E0D000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_ADC, &h44E004BCuL, 0)
    .ParOffs = i
  END WITH
END CONSTRUCTOR



FUNCTION AdcUdt.initialize CDECL( _
    BYVAL  Av AS UInt8  = PRUIO_DEF_AVRAGE _
  , BYVAL OpD AS UInt32 = PRUIO_DEF_ODELAY _
  , BYVAL SaD AS UInt8  = PRUIO_DEF_SDELAY) AS ZSTRING PTR

  WITH *Top
    VAR p = .MOffs + .DRam[InitParA]
    Init = p
    Conf = p + .DSize
  END WITH

  WITH *Conf
    IF .ClAd =  0 ORELSE _
       .REVISION = 0 THEN _ '                         subsystem disabled
                                  .DeAd = 0 : .ClVa = &h30000 : _
                              Init->DeAd = 0 : Init->ClAd = 0 : RETURN 0
    .ClVa = 2
    .SYSCONFIG = 0
    .CTRL = &b11

    VAR a = ABS((Av > 1) + (Av > 2) + (Av > 4) + (Av > 8)) SHL 2 _
      , d = OpD AND &h3FFFF
    FOR i AS LONG = 1 TO 8 '                       set default ADC steps
      WITH .St_p(i)
        .Confg = a + ((i - 1) SHL 19)
        .Delay = d + SaD SHL 24
      END WITH
    NEXT
  END WITH : RETURN 0
END FUNCTION



FUNCTION AdcUdt.configure CDECL( _
    BYVAL Samp AS UInt32 = PRUIO_DEF_SAMPLS _
  , BYVAL Mask AS UInt32 = PRUIO_DEF_STPMSK _
  , BYVAL  Tmr AS UInt32 = PRUIO_DEF_TIMERV _
  , BYVAL  Mds AS UInt16 = PRUIO_DEF_LSLMOD) AS ZSTRING PTR

  WITH *Top
    Value = 0 'set invalid in case of error

    IF 2 <> Conf->ClVa THEN '                      subsystem not enabled
      IF Samp < 2 ANDALSO _
         Mask = 0 THEN .DRam[2] = Samp _
                  ELSE .DRam[2] = 0 : .Errr = E5 '       ADC not enabled
      .DRam[3] = 0
      .DRam[4] = 0
      .DRam[5] = 0 :                                        RETURN .Errr
    END IF

    ChAz = 0
    VAR c = UBOUND(Conf->St_p) _
      , r = 0 _ ' first active step
      , d = 0uL ' duration of all steps
    FOR i AS LONG = c - 1 TO 0 STEP -1
      IF 0 = BIT(Mask, i) THEN CONTINUE FOR
      r = i '                                        find right-most bit
      ChAz += 1 '                                            count steps
      WITH Conf->St_p(r) '                calculate clock cycles (delay)
        VAR opd = .Delay AND &h3FFFF _
          , smd = .Delay SHR 24 _
          , avr = (.Confg SHR 2) AND &b111
        d += opd + 1 + (14 + smd) * (1 SHL avr)
      END WITH
    NEXT

    IF Samp < 2 THEN ' IO mode
      Samples = 1
      TimerVal = 0
      Value = CAST(ANY PTR, .DRam) + PRUIO_DAT_ADC + 4
    ELSE
      IF r < 1 THEN             .Errr = @"no step active" : RETURN .Errr
      Samples = Samp * ChAz
      IF (Samples SHL 1) > .ESize THEN _
                                 .Errr = @"out of memory" : RETURN .Errr
      d = (d * (Conf->ADC_CLKDIV + 1) * 1000) \ 24
      IF Tmr <= d ORELSE Tmr < 5000 THEN _
                           .Errr = @"sample rate too big" : RETURN .Errr
      Value = .ERam
      TimerVal = Tmr
    END IF
    WITH *Conf
      IF BIT(Mask, 31) THEN _ '                   adapt idle step config
        .IDLECONFIG = .St_p(r).Confg AND &b1111111111111111111100000

      Mask AND= (1 SHL c) - 1
      .STEPENABLE = Mask
    END WITH
    LslMode = IIF(Mds < 4, Mds, CAST(UInt16, 4))

    .DRam[5] = TimerVal
    .DRam[4] = LslMode
    .DRam[3] = Mask
    .DRam[2] = Samples
  END WITH : RETURN 0
END FUNCTION



FUNCTION AdcUdt.setStep CDECL( _
    BYVAL Stp AS UInt8 _
  , BYVAL ChN AS UInt8 _
  , BYVAL  Av AS UInt8  = PRUIO_DEF_AVRAGE _
  , BYVAL SaD AS UInt8  = PRUIO_DEF_SDELAY _
  , BYVAL OpD AS UInt32 = PRUIO_DEF_ODELAY) AS ZSTRING PTR

  WITH *Top
    IF 2 <> Conf->ClVa THEN                    .Errr = E5 : RETURN .Errr ' ADC not enabled
    IF Stp > UBOUND(Conf->St_p) THEN           .Errr = E0 : RETURN .Errr ' step number too big
    IF ChN > 7 THEN                            .Errr = E1 : RETURN .Errr ' channel number too big
  END WITH

  WITH *Conf.St_p(Stp)
    VAR a = ABS((Av > 1) + (Av > 2) + (Av > 4) + (Av > 8))
    .Confg = (a SHL 2) + (ChN SHL 19)
    .Delay = (OpD AND &h3FFFF) + (SaD SHL 24)
  END WITH : RETURN 0
END FUNCTION



FUNCTION AdcUdt.mm_trg_pin CDECL( _
    BYVAL Ball AS UInt8 _
  , BYVAL GpioV AS UInt8 = 0 _
  , BYVAL Skip AS UInt16 = 0) AS UInt32

  WITH *Top
    IF 2 <> Conf->ClVa THEN                        .Errr = E5 : RETURN 0 ' ADC not enabled
    IF Skip > 1023 THEN                            .Errr = E2 : RETURN 0 'too much values 2 skip
    BallCheck(" trigger", 0)
    'VAR g = .BallGpio(Ball) _ ' resulting GPIO (index and bit number)
      ', i = g SHR 5           ' index of GPIO

    'IF 2 <> .Gpio->Conf(i)->ClVa THEN _
    IF 2 <> .Gpio->Conf(.BallGpio(Ball) SHR 5)->ClVa THEN _
                        .Errr = @"GPIO subsystem not enabled" : RETURN 0
    IF 7 <> (.BallConf[Ball] AND &b111) THEN _
                 .Errr = @"pin must be in GPIO mode (mode 7)" : RETURN 0
  END WITH

  DIM AS UInt32 r =  (Skip SHL 22) _  ' number of samples to skip
        +               (1 SHL 21) _  ' GPIO bit
        +            (Ball SHL  8) _  ' Ball number
        + IIF(GpioV = 0, 1 SHL  7, 0) ' negative bit
  RETURN r
END FUNCTION



FUNCTION AdcUdt.mm_trg_ain CDECL( _
    BYVAL Stp AS UInt8 _
  , BYVAL AdcV AS Int32 _
  , BYVAL Rela AS UInt8 = 0 _
  , BYVAL Skip AS UInt16 = 0) AS UInt32

  WITH *Top
    IF 2 <> Conf->ClVa THEN                        .Errr = E5 : RETURN 0 ' ADC not enabled
    IF Stp > 16 THEN                               .Errr = E4 : RETURN 0 ' invalid step number
    IF Stp ANDALSO 0 = Conf->St_p(Stp).Confg THEN  .Errr = E3 : RETURN 0 ' trigger step not configured
    IF Skip > 1023 THEN                            .Errr = E2 : RETURN 0 ' too much values to skip
  END WITH

  VAR v = ABS(AdcV) SHR LslMode
  IF v < &hF THEN v = &hF ELSE IF v > &hFF0 THEN v = &hFF0

  DIM AS UInt32 r =  (Skip SHL 22) _ ' number of samples to skip
        +               (v SHL 8) _  ' sample AdcV to check
        + IIF(AdcV < 0,  1 SHL 7, 0) ' negative bit
  IF 0 = Stp THEN r += (1 SHL 5) _   ' all step bit,
             ELSE r += Stp - 1 _     ' or step number
                     + IIF(Rela, 1 SHL 6, 0)  ' and relative bit
  RETURN r
END FUNCTION



FUNCTION AdcUdt.mm_trg_pre CDECL( _
    BYVAL Stp AS UInt8 _
  , BYVAL AdcV AS Int32 _
  , BYVAL Samp AS UInt16 = 0 _
  , BYVAL Rela AS UInt8 = 0) AS UInt32

  WITH *Top
    IF 2 <> Conf->ClVa THEN                        .Errr = E5 : RETURN 0 ' ADC not enabled
    IF Stp > 16 THEN                               .Errr = E4 : RETURN 0 ' invalid step number
    IF Stp ANDALSO 0 = Conf->St_p(Stp).Confg THEN  .Errr = E3 : RETURN 0 ' trigger step not configured
    IF Stp ANDALSO 0 = (Conf->STEPENABLE AND (1 SHL Stp)) THEN _
                        .Errr = @"trigger step not activated" : RETURN 0
    VAR t = (Samp + 1) * ChAz
    IF t > ((16384 - PRUIO_DAT_ADC - 32) SHR 1) THEN _
                              .Errr = @"too much pre-samples" : RETURN 0
    IF t > Samples THEN _
                     .Errr = @"more pre-samples than samples" : RETURN 0
  END WITH

  VAR v = ABS(AdcV) SHR LslMode
  IF v < &hF THEN v = &hF ELSE IF v > &hFF0 THEN v = &hFF0

  DIM AS UInt32 r = (Samp SHL 22)  _   ' number of pre-samples
        +              (v SHL  8)  _   ' sample AdcV to check
        + IIF(AdcV < 0, 1 SHL  7, 0) _ ' negative bit
        +              (1 SHL  4)      ' pre-trigger bit
  IF 0 = Stp THEN r += (1 SHL  5)  _   ' all step bit,
             ELSE r +=  Stp -  1   _   ' or step number
        +     IIF(Rela, 1 SHL  6, 0)   ' and relative bit
  RETURN r
END FUNCTION