pruio_timer.bas

Go to the documentation of this file.

' PruIo global declarations.
#INCLUDE ONCE "pruio_globals.bi"
' Header for PWMSS part, containing modules QEP, CAP and PWM.
#INCLUDE ONCE "pruio_pwmss.bi"
' Header for TIMER part.
#INCLUDE ONCE "pruio_timer.bi"
' driver header file
#INCLUDE ONCE "pruio.bi"


#DEFINE TMRSS_CLK  24e6


CONSTRUCTOR TimerUdt(BYVAL T AS Pruio_ PTR)
  Top = T
  WITH *Top
    VAR i = .ParOffs
    InitParA = i
    i += 1 : .DRam[i] = &h48044000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_TIM4, &h44E00088uL, 0)

    i += 1 : .DRam[i] = &h48046000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_TIM5, &h44E000ECuL, 0)

    i += 1 : .DRam[i] = &h48048000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_TIM6, &h44E000F0uL, 0)

    i += 1 : .DRam[i] = &h4804A000uL
    i += 1 : .DRam[i] = IIF(.DevAct AND PRUIO_ACT_TIM7, &h44E0007CuL, 0)
    .ParOffs = i
  END WITH
END CONSTRUCTOR



FUNCTION TimerUdt.initialize CDECL() AS ZSTRING PTR
  WITH *Top
    VAR p_mem = .MOffs + .DRam[InitParA] _
      , p_raw = CAST(ANY PTR, .DRam) + PRUIO_DAT_TIMER

    FOR i AS LONG = 0 TO PRUIO_AZ_TIMER
      Raw(i) = p_raw
      p_raw += SIZEOF(TimerArr)

      Init(i) = p_mem
      Conf(i) = p_mem + .DSize

      WITH *Conf(i)
        IF .ClAd = 0 ORELSE _
           .TIDR = 0 THEN _ '                         subsystem disabled
                .DeAd = 0 : .ClVa = &h30000 : p_mem += 16 : _
                    Init(i)->DeAd = 0 : Init(i)->ClAd = 0 : CONTINUE FOR
        .ClVa = 2
        '.TCAR1 = 0
        '.TCAR2 = 0
      END WITH

      'WITH *Init(i)
        '.TCAR1 = 0
        '.TCAR2 = 0
      'END WITH

      p_mem += SIZEOF(TimerSet)
    NEXT
  END WITH : RETURN 0
END FUNCTION



FUNCTION TimerUdt.setValue CDECL( _
    BYVAL Ball AS UInt8 _
  , BYVAL Dur1 AS Float_t _
  , BYVAL Dur2 AS Float_t = 0. _
  , BYVAL Mode AS SHORT = 0) AS ZSTRING PTR

  STATIC AS CONST Float_t _
    d_min = 1000. * &h4 / TMRSS_CLK '' minimal duration [mSec]
  DIM AS UInt32 nr = 0

  WITH *Top
    SELECT CASE AS CONST Ball
    CASE &h24 : nr = 0 : IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A) ' P8_07, GP1_5, R7 mode 2
    CASE &h25 : nr = 3 : IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A) ' P8_08, GP1_6, T7 mode 2
    CASE &h26 : nr = 2 : IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A) ' P8_10
    CASE &h27 : nr = 1 : IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A) ' P8_09
    CASE &h5A : nr = 3 : IF ModeCheck(Ball,5) THEN ModeSet(Ball, &h0D) ' P2_27, E18 mode 5
    CASE &h6C : nr = 0 : IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A) ' P2_31, A15 mode 2
    CASE &h67 : IF ModeCheck(Ball,4) THEN ModeSet(Ball, &h0C) ' P9_28
      RETURN .PwmSS->cap_tim_set(2, Dur1, Dur2, Mode)
    CASE &h5D : IF ModeCheck(Ball,4) THEN ModeSet(Ball, &h0C) ' JT_05
      RETURN .PwmSS->cap_tim_set(1, Dur1, Dur2, Mode)
    CASE &h59 : IF ModeCheck(Ball,0) THEN ModeSet(Ball, &h08) ' P9_42
      RETURN .PwmSS->cap_tim_set(0, Dur1, Dur2, Mode)
    CASE ELSE :                                      .Errr = E1 : RETURN E1 ' no Timer pin
    END SELECT

    IF 2 <> Conf(nr)->ClVa THEN                      .Errr = E0 : RETURN E0 ' TIMER not enabled
    'IF ModeCheck(Ball,2) THEN ModeSet(Ball, &h0A)

    VAR dur = Dur1 + Dur2 ' [mSec]
    WITH *Conf(nr)
      Raw(nr)->CMax = 0
      SELECT CASE dur
      CASE IS <= 0. : .TCLR = IIF(Mode AND &b01, TimHigh, Tim_Low) ' stop
      CASE IS < d_min :                          Top->Errr = E3 : RETURN E3 ' duration too short
      CASE ELSE
        VAR cnt = CULNGINT(.001 * dur * TMRSS_CLK)
        SELECT CASE AS CONST (cnt SHR 32) '' faster than LOG -> prescaler
        CASE   0        : .TCLR = TimMode
        CASE   1        : .TCLR = TimMode OR &b100000 : cnt SHR= 1
        CASE   2 TO   3 : .TCLR = TimMode OR &b100100 : cnt SHR= 2
        CASE   4 TO   7 : .TCLR = TimMode OR &b101000 : cnt SHR= 3
        CASE   8 TO  15 : .TCLR = TimMode OR &b101100 : cnt SHR= 4
        CASE  16 TO  31 : .TCLR = TimMode OR &b110000 : cnt SHR= 5
        CASE  32 TO  63 : .TCLR = TimMode OR &b110100 : cnt SHR= 6
        CASE  64 TO 127 : .TCLR = TimMode OR &b111000 : cnt SHR= 7
        CASE 128 TO 255 : .TCLR = TimMode OR &b111100 : cnt SHR= 8
        CASE ELSE :                              Top->Errr = E4 : RETURN E4 ' duration too long
        END SELECT
        .TLDR = &hFFFFFFFFuL - cnt

        VAR match = CULNG(Dur1 / dur * cnt)
        SELECT CASE match
        CASE IS <= 2      : .TMAR = &hFFFFFFFEuL : .TCRR = .TMAR : .TLDR += 1
          .TCLR XOR= &b0110000000000  ' toggle on overflow
        CASE IS > cnt - 2 : .TMAR = .TLDR + 2    : .TCRR = .TMAR + 2 : .TLDR += 1
          .TCLR XOR= &b1110000000000  ' pulse instead of toggle
        CASE ELSE         : .TMAR = &hFFFFFFFFuL - match : .TCRR = .TMAR + 2
        END SELECT

        IF Mode AND &b01 THEN .TCLR XOR= &b0000010000000 ' invers
        IF Mode >= &b10 THEN ' one-shot
          IF 0.01 >= Dur1 THEN                   Top->Errr = E3 : RETURN Top->Errr ' duration too short
          Raw(nr)->CMax = (Mode AND &b111111110) SHR 1
          .TCLR OR= &b100000000 ' one shot, bit 8!!
        END IF
      END SELECT
    END WITH

    IF .DRam[0] > PRUIO_MSG_IO_OK                            THEN RETURN 0

    PruReady(1) ' wait, if PRU is busy (should never happen)
    .DRam[5] = Conf(nr)->TMAR
    .DRam[4] = Conf(nr)->TLDR
    .DRam[3] = Conf(nr)->TCRR
    .DRam[2] = Conf(nr)->DeAd
    .DRam[1] = Conf(nr)->TCLR OR (PRUIO_COM_TIM_TIM SHL 24)
  END WITH :                                                      RETURN 0
END FUNCTION



FUNCTION TimerUdt.Value CDECL( _
    BYVAL Ball AS UInt8 _
  , BYVAL Dur1 AS Float_t PTR _
  , BYVAL Dur2 AS Float_t PTR) AS ZSTRING PTR

  IF Dur1 = 0 ORELSE Dur2 = 0 THEN Top->Errr = @"pass pointers" : RETURN Top->Errr
  DIM AS Uint32 nr
  WITH *Top
    SELECT CASE AS CONST Ball
    CASE &h24 : nr = 0 : IF ModeCheck(Ball,2) THEN RETURN E2 ' P8_07, GP1_5, R7 mode 2
    CASE &h25 : nr = 3 : IF ModeCheck(Ball,2) THEN RETURN E2 ' P8_08, GP1_6, T7 mode 2
    CASE &h26 : nr = 2 : IF ModeCheck(Ball,2) THEN RETURN E2 ' P8_10
    CASE &h27 : nr = 1 : IF ModeCheck(Ball,2) THEN RETURN E2 ' P8_09
    CASE &h5A : nr = 3 : IF ModeCheck(Ball,5) THEN RETURN E2 ' P2_27, E18 mode 5
    CASE &h6C : nr = 0 : IF ModeCheck(Ball,2) THEN RETURN E2 ' P2_31, A15 mode 2
    CASE &h67 : RETURN IIF(ModeCheck(Ball,4), E2, .PwmSS->cap_tim_get(2, Dur1, Dur2)) ' P9_28
    CASE &h5D : RETURN IIF(ModeCheck(Ball,4), E2, .PwmSS->cap_tim_get(1, Dur1, Dur2)) ' JT_05
    CASE &h59 : RETURN IIF(ModeCheck(Ball,0), E2, .PwmSS->cap_tim_get(0, Dur1, Dur2)) ' P9_42
    CASE ELSE :                                   .Errr = E1 : RETURN E1 ' no Timer pin
    END SELECT
  END WITH
  WITH *Conf(nr)
    VAR dur = *Dur1 + *Dur2 _ ' [mSec]
     , dmax = 1000. * &hFFFFFFFF00uLL / TMRSS_CLK _
     , dmin = 1000. * 4 / TMRSS_CLK
    SELECT CASE dur
    CASE IS <= 0. ' get current
      IF 2 <> .ClVa THEN                         Top->Errr = E0 : RETURN E0 ' TIMER subsystem not enabled
      IF BIT(.TCLR, 13) THEN                     Top->Errr = E2 : RETURN E2 ' pin not in TIMER mode
      IF BIT(.TCLR, 6) THEN ' running
        VAR f = IIF(BIT(.TCLR, 5), (1 SHL ((.TCLR SHR 2) AND &b111)) * 2000., 1000.)
        *Dur1 = f * (       .TMAR - .TLDR) / TMRSS_CLK
        *Dur2 = f * (&hFFFFFFFFuL - .TMAR) / TMRSS_CLK
      ELSE ' stopped
        *Dur2 = 0.
        *Dur1 = 0.
      END IF
    CASE IS <= dmin ' get minimal
      *Dur1 = dmin
      *Dur2 = dmin / 2
    CASE IS >= dmax ' get maximal, splited by ratio Dur1/Dur2
      *Dur1 = *Dur1 / dur * dmax
      *Dur2 = *Dur2 / dur * dmax
    CASE ELSE '!!! log !!!
      VAR cnt = CULNGINT(.001 * dur * TMRSS_CLK), n = cnt SHR 32
      IF n THEN n = LOG(n) / LOG2 : cnt = (cnt SHR n) SHL n
      *Dur1 = 1000. * CULNGINT(*Dur1 / dur * cnt) / TMRSS_CLK
      *Dur2 = 1000. * CULNGINT(*Dur2 / dur * cnt) / TMRSS_CLK
    END SELECT
  END WITH :                                                     RETURN 0
END FUNCTION



FUNCTION TimerUdt.pwm_set CDECL( _
    BYVAL Nr AS UInt8 _
  , BYVAL Freq AS Float_t _
  , BYVAL Duty AS Float_t = 0.) AS ZSTRING PTR

  STATIC AS CONST Float_t _
    f_min = TMRSS_CLK / &hFFFFFFFF00uLL _'' minimal frequency
  , f_max = TMRSS_CLK / &h4 ''              maximal frequency
  STATIC AS UInt32 r = 0 _
  , cnt(...) = {0, 0, 0, 0} _  '' initial timer periods
  , cmp(...) = {0, 0, 0, 0}    '' initial timer match values

  WITH *Top
    IF 2 <> Conf(Nr)->ClVa THEN                   .Errr = E0 : RETURN E0 ' TIMER not enabled

    IF Freq < 0. THEN ' frequency unchanged
      IF 0 = cnt(Nr) THEN              .Errr = .PwmSS->E1 : RETURN .Errr ' set frequency first
      r = PwmMode OR (Conf(Nr)->TCLR AND &b111100)
    ELSE
      IF Freq < f_min ORELSE _
         Freq > f_max THEN             .Errr = .PwmSS->E2 : RETURN .Errr ' frequency not supported
      VAR x = CULNGINT(TMRSS_CLK / Freq)
      SELECT CASE AS CONST x SHR 32 '' faster than LOG -> set prescaler
      CASE   0        : cnt(Nr) = x       : r = PwmMode
      CASE   1        : cnt(Nr) = x SHR 1 : r = PwmMode OR &b100000
      CASE   2 TO   3 : cnt(Nr) = x SHR 2 : r = PwmMode OR &b100100
      CASE   4 TO   7 : cnt(Nr) = x SHR 3 : r = PwmMode OR &b101000
      CASE   8 TO  15 : cnt(Nr) = x SHR 4 : r = PwmMode OR &b101100
      CASE  16 TO  31 : cnt(Nr) = x SHR 5 : r = PwmMode OR &b110000
      CASE  32 TO  63 : cnt(Nr) = x SHR 6 : r = PwmMode OR &b110100
      CASE  64 TO 127 : cnt(Nr) = x SHR 7 : r = PwmMode OR &b111000
      CASE 128 TO 255 : cnt(Nr) = x SHR 8 : r = PwmMode OR &b111100
      CASE ELSE :                      .Errr = .PwmSS->E2 : RETURN .Errr ' frequency not supported
      END SELECT
    END IF
    Conf(Nr)->TLDR = &hFFFFFFFFuL - cnt(Nr)

    IF Duty >= 0. THEN ' change duty
      cmp(Nr) = IIF(Duty >= 1., cnt(Nr), CUINT(cnt(Nr) * Duty))
      SELECT CASE cmp(Nr)
      CASE IS <=           1 : r = Tim_Low
      CASE IS >= cnt(Nr) - 1 : r = TimHigh
      CASE ELSE : Conf(Nr)->TMAR = Conf(Nr)->TLDR + cmp(Nr) - 1
      END SELECT
    END IF

    IF Conf(Nr)->TCLR = r THEN ' control reg unchanged
      r = 0
    ELSE
      Conf(Nr)->TCLR = r
      Conf(Nr)->TCRR = &hFFFFFFFEuL
    END IF

    IF .DRam[0] > PRUIO_MSG_IO_OK THEN                          RETURN 0

    PruReady(1) ' wait, if PRU is busy (should never happen)
    .DRam[5] = Conf(Nr)->TCRR
    .DRam[4] = Conf(Nr)->TMAR
    .DRam[3] = Conf(Nr)->TLDR
    .DRam[2] = Conf(Nr)->DeAd
    .DRam[1] = r OR (PRUIO_COM_TIM_PWM SHL 24)
  END WITH :                                                    RETURN 0
END FUNCTION



FUNCTION TimerUdt.pwm_get CDECL( _
    BYVAL Nr AS UInt8 _
  , BYVAL Freq AS Float_t PTR = 0 _
  , BYVAL Duty AS Float_t PTR = 0) AS ZSTRING PTR

  WITH *Conf(Nr)
    IF 2 <> .ClVa THEN Top->Errr = E0   /' TIMER disabled '/ : RETURN E0

    VAR cnt = &hFFFFFFFFuLL - .TLDR + 1 _
      , pre = (.TCLR AND &b111100) SHR 2
    SELECT CASE .TCLR
    CASE TimHigh : IF Duty THEN *Duty = 1.
    CASE Tim_Low : IF Duty THEN *Duty = 0.
    CASE ELSE
      IF (PwmMode AND .TCLR) <> PwmMode THEN Top->Errr = E2 :  RETURN E2 ' TIMER not in PWM output mode
      IF Duty THEN *Duty = (.TMAR -.TLDR + 1) / cnt
    END SELECT
    IF Freq THEN *Freq = TMRSS_CLK / (cnt SHL IIF(pre, (pre AND &b111) + 1, 0))
  END WITH :                                                    RETURN 0
END FUNCTION