pruss_add.bas

Go to the documentation of this file.

#include ONCE "BBB/pruio.bi" ' the library (for pinmuxing)
#include ONCE "BBB/pruio_pins.bi" ' CPU balls human readable
#include ONCE "BBB/pruio_prussdrv.bi" ' user space part of uio_pruss



FUNCTION load_firmware(BYVAL IRam AS UInt32) AS Int32
  DIM AS CONST UInt32 PRUcode(...) =  { _
    &h240000E0 _
  , &hF104E081 _
  , &h30830002 _
  , &h00E2E1E1 _
  , &hE1002081 _
  , &h1004041F _
  , &h2A000000 _
  , &h21000100 }
  VAR l = (UBOUND(PRUcode) + 1) * SIZEOF(PRUcode)
  RETURN 0 >= prussdrv_pru_write_memory(IRam, 0, @PRUcode(0), l)
END FUNCTION


VAR io = NEW PruIo(PRUIO_ACT_PRU1) 
DO
  DIM AS UInt32 _
      pru_num _  
    , pru_iram _ 
    , pru_dram _ 
    , pru_intr   
'
' Check init success
'
  IF io->Errr THEN _
                  ?"initialisation failed (" & *io->Errr & ")" : EXIT DO

  IF io->PruNo THEN '                               we use the other PRU
    pru_num = 0
    pru_iram = PRUSS0_PRU0_IRAM
    pru_dram = PRUSS0_PRU0_DRAM
    pru_intr = PRU0_ARM_INTERRUPT
  ELSE
    pru_num = 1
    pru_iram = PRUSS0_PRU1_IRAM
    pru_dram = PRUSS0_PRU1_DRAM
    pru_intr = PRU0_ARM_INTERRUPT ' libpruio uses PRU1_ARM_INTERRUPT!
  END IF
'
' Now prepare the other PRU
'
  IF prussdrv_open(PRU_EVTOUT_0) THEN _ ' note: libpruio uses PRU_EVTOUT_5
                                       ?"prussdrv_open failed" : EXIT DO
  ' Note: no prussdrv_pruintc_init(), libpruio did it already

  IF load_firmware(pru_iram) < 0 THEN _
                          ?"failed loading PRUSS instructions" : EXIT DO
'
' Pass parameters to PRU
'
  DIM AS UInt32 PTR dram 
  prussdrv_map_prumem(pru_dram, CAST(ANY PTR, @dram)) ' get dram pointer
  dram[1] = 23 ' start value
  dram[2] = 7  ' value to add
  dram[3] = 67 ' loop count (max 16 bit = 65536)
  dram[4] = pru_intr + 16 ' the interrupt we're waiting for
'
' Execute
'
  ?"instructions loaded, starting PRU-" & pru_num
  prussdrv_pru_enable(pru_num) ' start
  prussdrv_pru_wait_event(PRU_EVTOUT_0) ' wait until finished
  prussdrv_pru_clear_event(PRU_EVTOUT_0, pru_intr) ' clear interrupt (optional, useful when starting again)
'
' Check result
'
  IF dram[0] = (dram[1] + (dram[2] * dram[3])) THEN
    ?"Test OK " & dram[0] & " = " & dram[1] & " + (" & dram[2] & " * " & dram[3] & ")"
  ELSE
    ?"Test failed " & dram[0] & " <> " & dram[1] & " + (" & dram[2] & " * " & dram[3] & ")"
  END IF

  prussdrv_pru_disable(pru_num) ' disable PRU
  ' note: no prussdrv_exit(), libpruio does it in the destructor
LOOP UNTIL 1

DELETE io ' destroy driver structure

'' help Doxygen to document the main code
'&/** The main function. */
'&int main() {PruIo::PruIo(); PruIo::~PruIo();}