rb_oszi.bas

Go to the documentation of this file.

' include libpruio
#INCLUDE ONCE "BBB/pruio.bi"
' include FreeBASIC grafics
#INCLUDE ONCE "fbgfx.bi"

VAR S_W = 0 _ 
  , S_H = 0 _ 
  , BPP = 0 _ 
  , full = fb.GFX_FULLSCREEN 
SCREENINFO S_W, S_H, BPP '                         get screen resolution
IF LEN(COMMAND) THEN '                   customized resolution required?
  VAR p = INSTR(COMMAND, "x") _       
    , w = VALINT(COMMAND) _           
    , h = VALINT(MID(COMMAND, p + 1)) 
  IF p ANDALSO w ANDALSO h THEN
    IF w < S_W - 4 ANDALSO h < S_H - 24 THEN full = fb.GFX_WINDOWED
    S_W = IIF(w < S_W, w, S_W) '           set maximum custom resolution
    S_H = IIF(h < S_H, h, S_H)
  ELSE
    PRINT "set resolution like 640x400"
    END
  END IF
END IF

SCREENRES S_W, S_H, BPP, 2, full '                 set screen resolution
IF 0 = SCREENPTR THEN                  PRINT "no grafic available" : END


DIM AS UInt32 _
  col(...) = { _
    RGBA(  0,   0,   0, 255) _
  , RGBA(255,   0,   0, 255) _
  , RGBA(  0, 255,   0, 255) _
  , RGBA(  0,   0, 255, 255) _
  , RGBA(255, 255,   0, 255) _
  , RGBA(255,   0, 255, 255) _
  , RGBA(  0, 255, 255, 255) _
  , RGBA(127, 127, 127, 255) _
    }


#MACRO DRAW_GRAF()
  LINE (0, 0) - (S_W, S_H), RGB(250, 250, 250), BF
  FOR c AS INTEGER = 0 TO .Adc->ChAz - 1
    VAR i = c + .Adc->ChAz
    LINE (0, S_H - CUINT(p[c] * scale)) - _
         (1, S_H - CUINT(p[i] * scale)), col(c)
    FOR x AS INTEGER = 2 TO S_W
      i += .Adc->ChAz
      LINE - (x, S_H - CUINT(p[i] * scale)), col(c)
    NEXT
  NEXT
#ENDMACRO

VAR io = NEW PruIo() 

WITH *io
  DO
    IF .Errr THEN ?"NEW failed: " & *.Errr : EXIT DO

    VAR samp = S_W SHL 1 
    S_W -= 1
    S_H -= 1
    VAR scale = S_H / 65520 

    IF .config(samp, &b100100000, 4e5) THEN _ '      configure steps 5+8
                                   ?"config failed: " & *.Errr : EXIT DO

    VAR half = .Adc->Samples SHR 1 _ 
         , p = .Adc->Value           
    IF .rb_start() THEN _ '                       start ring buffer mode
                                 ?"rb_start failed: " & *.Errr : EXIT DO
    DO '                                  read ring buffer and draw graf
      WHILE .DRam[0] < half : SLEEP 1 : WEND
      DRAW_GRAF()
      p += half
      SCREENSET 0, 1

      WHILE .DRam[0] > half : SLEEP 1 : WEND
      DRAW_GRAF()
      p -= half
      SCREENSET 1, 0
    LOOP UNTIL LEN(INKEY()) : ?
  LOOP UNTIL 1
  IF .Errr THEN SLEEP
END WITH

DELETE(io)

'' help Doxygen to document the main code
'&/** The main function. */
'&int main() {PruIo::PruIo(); PruIo::config(); PruIo::~PruIo();}