pwm_adc.bas

Go to the documentation of this file.

' include libpruio
#INCLUDE ONCE "BBB/pruio.bi"
' include the convenience macros for header pins
#INCLUDE ONCE "BBB/pruio_pins.bi"
' include FB grafics
#INCLUDE ONCE "fbgfx.bi"

VAR S_W = 0 _ 
  , S_H = 0 _ 
  , BPP = 0 _ 
  , full = fb.GFX_FULLSCREEN 
SCREENINFO S_W, S_H, BPP '                         get screen resolution

IF LEN(COMMAND) THEN '                   customized resolution required?
  VAR p = INSTR(COMMAND, "x") _       
    , w = VALINT(COMMAND) _           
    , h = VALINT(MID(COMMAND, p + 1)) 
  IF p ANDALSO w ANDALSO h THEN
    IF w < S_W - 4 ANDALSO h < S_H - 24 THEN full = fb.GFX_WINDOWED
    S_W = IIF(w < S_W, w, S_W) '           set maximum custom resolution
    S_H = IIF(h < S_H, h, S_H)
  ELSE
    PRINT "set resolution like 640x400"
    END
  END IF
END IF

SCREENRES S_W, S_H, BPP, 2, full '                 set screen resolution
IF 0 = SCREENPTR THEN                  PRINT "no grafic available" : END


DIM AS UInt32 _
  col(...) = { _
    RGBA(255,   0,   0, 255) _
  , RGBA(  0, 255,   0, 255) _
  , RGBA(  0,   0, 255, 255) _
    }


DIM AS UInt32 _
  last(...) = { _
    0 _
  , 0 _
  , 0 _
  , 0 _
  , 0 _
  , 0 _
  , 0 _
  , 0 _
    }


TYPE PWM_PIN
  AS UInt8 _
    Pin        
  AS Float_t _
    Freq _     
  , Duty       
  AS ZSTRING PTR _
    Nam        
END TYPE


DIM AS PWM_PIN ch(...) = { _
    TYPE<PWM_PIN>(P9_14, 2.5, .5, @"P9_14 (A)") _
  , TYPE<PWM_PIN>(P9_16, 2.5, .2, @"P9_16 (B)") _
  , TYPE<PWM_PIN>(P9_42, 2.5, .8, @"P9_42 (C)") _
  }

VAR io = NEW PruIo 

WITH *io
  DO
    IF .Errr THEN ?"NEW failed: " & *.Errr : EXIT DO

    FOR i AS INTEGER = 0 TO UBOUND(ch) '              configure PWM pins
      IF .Pwm->setValue(ch(i).Pin, ch(i).Freq, ch(i).Duty) THEN _
         ?"failed setting " & *ch(i).nam & " (" & *.Errr & ")" : EXIT DO
    NEXT

    IF .config(1, &b1110) THEN _ ' configure steps 1, 2, 3 (AIN-[0,1,2])
      ?"config failed: " & *.Errr & " --> " & .DRam[0] : SLEEP : EXIT DO

    VAR scale = S_H / 65520 _   
          , x = 0 _             
        , gap = 1 _             
       , xmax = S_W - gap - 1 _ 
          , m = 0 _             
          , n = 2 _             
         , fg = RGB(0, 0, 0) _      
         , bg = RGB(250, 250, 250)  
    FOR i AS INTEGER = 0 TO UBOUND(ch) '                get start values
      last(i) = S_H - CUINT(.Adc->Value[i + 1] * scale)
    NEXT

    WINDOWTITLE(*ch(n).nam _
            & ": Frequency = " & ch(n).Freq & " Hz" _
            & ", Duty = " & (ch(n).Duty) * 100) & "%"
    COLOR fg, bg
    CLS
    DO
      VAR k = ASC(INKEY()) 
      IF k THEN
        SELECT CASE AS CONST k '                react on user keystrokes
        CASE ASC("A"), ASC("a") : m = BITRESET(&hFF, 0): n = 256 : ch(0).Freq = ch(1).Freq 'PWMSS 1, output PWM-A (P9_14)
        CASE ASC("B"), ASC("b") : m = BITRESET(&hFF, 1): n = 257 : ch(1).Freq = ch(0).Freq 'PWMSS 1, output PWM-B (P9_16)
        CASE ASC("C"), ASC("c") : m = BITRESET(&hFF, 2): n = 258 'PWMSS 0, output eCAP  (P9_42)
        CASE ASC("0") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.0
        CASE ASC("1") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.1
        CASE ASC("2") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.2
        CASE ASC("3") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.3
        CASE ASC("4") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.4
        CASE ASC("5") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.5
        CASE ASC("6") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.6
        CASE ASC("7") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.7
        CASE ASC("8") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.8
        CASE ASC("9") : m = BITRESET(&hFF, n) : ch(n).Duty = 0.9
        CASE ASC(","), ASC(".") : m = BITRESET(&hFF, n) : ch(n).Duty = 1.0
        CASE ASC("+") : IF ch(n).Freq < 5.0 THEN ch(n).Freq += .5
        CASE ASC("-") : IF ch(n).Freq > 0.9 THEN ch(n).Freq -= .5
        CASE ASC("*") : ch(n).Freq = 5.0
        CASE ASC("/") : ch(n).Freq = .5
        CASE 13 : m = 0 : n += 256
        CASE ELSE : EXIT DO '                                     finish
        END SELECT

        IF n > UBOUND(ch) THEN
          n -= 256
        ELSE
          IF .Pwm->setValue(ch(n).Pin, ch(n).Freq, ch(n).Duty) THEN _
                  ?"failed setting PWM value (" & *.Errr & ")" : EXIT DO
        END IF

        WINDOWTITLE(*ch(n).nam _
            & ": Frequency = " & ch(n).Freq & " Hz" _
            & ", Duty = " & (ch(n).Duty) * 100) & "%"
      END IF

      LINE (x + 1, 0) - STEP (gap, S_H), bg, BF
      FOR i AS INTEGER = 0 TO UBOUND(ch) '                    draw lines
        IF BIT(m, i) THEN CONTINUE FOR
        VAR neu = S_H - CUINT(.Adc->Value[i + 1] * scale) 
        LINE (x, last(i)) - (x + gap, neu), col(i)
        last(i) = neu
        LINE (0, 0) - STEP (gap, S_H), 0, BF
      NEXT
      x += gap : IF x > xmax THEN x = 0
      SLEEP 1
    LOOP : ?
  LOOP UNTIL 1
  IF .Errr THEN SLEEP
END WITH

DELETE(io)

'' help Doxygen to document the main code
'&/** The main function. */
'&int main() {PruIo::PruIo(); PwmMod::setValue(); PruIo::config(); PruIo::~PruIo();}