sos.bas

Go to the documentation of this file.

' include libpruio
#INCLUDE ONCE "BBB/pruio.bi"


#DEFINE PIN 24

#DEFINE OUT_K .Gpio->setValue(PIN, pinmode + 128) : SLEEP 150 _
            : .Gpio->setValue(PIN, pinmode) : SLEEP 100

#DEFINE OUT_L .Gpio->setValue(PIN, pinmode + 128) : SLEEP 350 _
            : .Gpio->setValue(PIN, pinmode) : SLEEP 100

#DEFINE OUT_S OUT_K : OUT_K : OUT_K : SLEEP 150

#DEFINE OUT_O OUT_L : OUT_L : OUT_L : SLEEP 150

' *****  main  *****


'VAR io = NEW PruIo(PRUIO_ACT_FREMUX OR PRUIO_ACT_GPIO1)
VAR io = NEW PruIo()

WITH *io
  DO
    IF .Errr THEN    ?"initialisation failed (" & *.Errr & ")" : EXIT DO

    VAR pinmode = .BallConf[PIN] 

    IF .config(1, 0) THEN    ?"config failed (" & *.Errr & ")" : EXIT DO

    ?"watch SOS code on user LED 3 (near ethernet connector)"
    ?
    ?"execute the following command to get rid of mmc1 triggers"
    ?"  sudo su && echo none > /sys/class/leds/beaglebone:green:usr3/trigger && echo 0 > /sys/class/leds/beaglebone:green:usr3/brightness && exit"
    ?
    ?"press any key to quit"
    DO '                           print current state (until keystroke)
      ?!"S"; : OUT_S : IF .Errr THEN ?"blink failed (" & *.Errr & ")": EXIT DO
      ?!"O"; : OUT_O
      ?!"S"; : OUT_S
      ?!"\r   \r"; : SLEEP 1500
    LOOP UNTIL LEN(INKEY()) : ?
    if .Gpio->setValue(PIN, pinmode) then _ '       reset LED (cosmetic)
          ?"reset failed (" & *.Errr & ") press any key to quit" : SLEEP
  LOOP UNTIL 1
END WITH

DELETE io '                    reset ADC, PinMux and GPIOs, clear memory

'' help Doxygen to document the main code
'&/** The main function. */
'&int main() {PruIo::PruIo(); PruIo::config(); GpioUdt::setValue(); PruIo::~PruIo();}