parser_nmea.bas

Go to the documentation of this file.

#INCLUDE ONCE "Gir/GLib-2.0.bi"
#INCLUDE ONCE "parser_nmea.bi"
#INCLUDE ONCE "track_loader.bi"
#INCLUDE ONCE "datetime.bi"



CONSTRUCTOR NMEA(BYVAL Par AS TrackLoader PTR)
WITH *Par
  VAR i = 0, tind = 28, t = @.Buff[0], s = CAST(ZSTRING PTR, t), check = 0
  Dat = t
  DO
    SELECT CASE AS CONST t[i]
    CASE 0 : EXIT DO
    CASE 1 TO 31  : t[i] = 0
    CASE ASC(",") : t[i] = 0 : Tok(tind) = @t[i+1] : tind += 1
    CASE ASC("*")
      IF check <> VALINT("&h" & LEFT(S[i+1], 2)) _
        THEN Enr += 1 : ?"invalid checksum (" & Lin & "): &h";HEX(check, 2);" <> &h";LEFT(S[i+1], 2)
      i += 2
    CASE ASC("$")
      check = 0 ' reset checksum
      FOR j AS INTEGER = i+1 TO i+72
        SELECT CASE AS CONST t[j]
        CASE 0, 42 : EXIT FOR ' exit on end of buffer or asterix character
        END SELECT : check XOR= t[j]
      NEXT
      IF t[i+3] = ASC("G") THEN
        IF tind <> 28 THEN Enr += 1 : ?"RMC check failed (" & Lin & ") " & tind
        tind = 0
        IF Lin THEN Eval(@Tok(0)) ':        ?hey(DaTi(@Tok(0))),hey(LaLo(@Tok(2))),hey(LaLo(@Tok(4)))
      ELSE
        IF tind <> 15 THEN tind = 15 : Enr += 1 : ?"GGA check failed (" & Lin & ") " & tind
      END IF : Lin += 1
      Tok(tind) = @t[i]
      tind += 1
      i += 5
    END SELECT : i += 1
  LOOP : .Byt = i : IF Lin THEN Eval(@Tok(0))
  .Siz = Dat - CAST(ANY PTR, .Buff)
END WITH
END CONSTRUCTOR



FUNCTION NMEA.Val_(BYVAL S AS ZSTRING PTR) AS float
  IF S[0] = 0 THEN Enr += 1 : ?"missing number (" & Lin & ")" : RETURN NaN
  RETURN g_ascii_strtod(*S, NULL)
END FUNCTION



FUNCTION NMEA.DaTi(BYVAL S AS ZSTRING PTR PTR) AS DOUBLE
  IF 6 <> LEN(*S[1]) ORELSE _
     6 <> LEN(*S[24]) THEN Enr += 1 : ?"invalid date/time (" & Lin & ")" : RETURN NaN
  RETURN _
    DATESERIAL( _
      VALINT(MID(*S[24], 5, 2)) + 2000 _
    , VALINT(MID(*S[24], 3, 2)) _
    , VALINT(MID(*S[24], 1, 2)) ) _
  + TIMESERIAL( _
      VALINT(MID(*S[1], 1, 2)) _
    , VALINT(MID(*S[1], 3, 2)) _
    , VALINT(MID(*S[1], 5, 2)) )
END FUNCTION



FUNCTION NMEA.LaLo(BYVAL S AS ZSTRING PTR PTR) AS DOUBLE
  VAR p = INSTR(*S[0], ".") - 2, f = NaN
  SELECT CASE AS CONST PEEK(UBYTE, S[1])
  CASE ASC("N"), ASC("E") : IF p > 1 THEN f =  Deg2Rad
  CASE ASC("S"), ASC("W") : IF p > 1 THEN f = -Deg2Rad
  END SELECT
  RETURN f * (g_ascii_strtod(MID(*S[0], p), NULL) / 60 + VALINT(LEFT(*S[0], p-1)))
END FUNCTION



FUNCTION NMEA.Eval(BYVAL S AS ZSTRING PTR PTR) AS TrP PTR
  IF *S[2] <> *S[18] ORELSE _
     *S[3] <> *S[19] ORELSE _
     *S[4] <> *S[20] ORELSE _
     *S[5] <> *S[21] THEN Enr += 1 : ?"location mismatch (" & Lin & ")" : RETURN Dat
  VAR r = NEW(Dat) TrP ( _
    DaTi(S) _              
  , LaLo(@S[2]) _          
  , LaLo(@S[4]) _          
  , Val_(*S[9]) _          
  , Val_(*S[22]) * 1.852 _ 
  , Val_(*S[23]) _         
  , 0 ,0)
  Dat += SIZEOF(TrP)
  RETURN r
END FUNCTION