track_store.bas

Go to the documentation of this file.

#INCLUDE ONCE "Gir/Gtk-3.0.bi"
#INCLUDE ONCE "track_layer.bi"
#INCLUDE ONCE "track_store.bi"
#INCLUDE ONCE "gui.bi"



FUNCTION TS_add._find CDECL( _
    BYVAL Model AS GtkTreeModel PTR _
  , BYVAL Path AS GtkTreePath PTR _
  , BYVAL Iter AS GtkTreeIter PTR _
  , BYVAL UserData AS gpointer) AS gboolean
WITH *CAST(TS_add PTR, UserData)
  DIM AS gchar PTR n, p
  gtk_tree_model_get(Model, Iter _
    , COL____NAME, @n _
    , COL____PATH, @p _
    , COL__LOADER, @.Loa _
    , -1)
  IF .Loa THEN
    ' check if file (path+name) is present
    IF .Nam = *n ANDALSO .Fol = *p THEN .Got = TRUE
  ELSE
    ' check if folder is present -> get iter
    IF NULL = p  ANDALSO .Fol = *n THEN .Par = gtk_tree_iter_copy(Iter)
  END IF : g_free(p) : g_free(n) : RETURN .Got
END WITH
END FUNCTION



CONSTRUCTOR TS_add(BYVAL N AS CONST gchar PTR)
WITH *GUI
  VAR p = INSTRREV(*N, *G_DIR_SEPARATOR_S)
  Nam = MID(*N, p+1)
  Fol = LEFT(*N, p)
  VAR model = GTK_TREE_MODEL(.STO)
  gtk_tree_model_foreach(model _
    , @TS_add._find(), CAST(gpointer, @THIS))
  IF Got THEN EXIT CONSTRUCTOR

  VAR tl = NEW TrackLoader(N)
  IF tl->Az >= 0 THEN Loa = CAST(gpointer, tl) _
                 ELSE ?"**load error: ";*tl->Errr;" in file ";*N : DELETE(tl) : EXIT CONSTRUCTOR

  DIM AS GtkTreeIter new_par, iter
  VAR sto = GTK_TREE_STORE(.STO)
  IF NULL = Par THEN
    gtk_tree_store_insert_with_values(sto, @new_par, NULL, -1 _
      , COL__ENABLE, FALSE _
      , COL__SELECT, FALSE _
      , COL_VISIBLE, FALSE _
      , COL____NAME, Fol _
      , COL____PATH, NULL _
      , COL__LOADER, NULL _
      ,-1)
  END IF

  VAR def = track_layer_get_default(TRACK_LAYER(.TRL))
  IF def THEN
    gtk_tree_store_insert_with_values(sto, @iter, IIF(Par, Par, @new_par), -1 _
      , COL__ENABLE, TRUE _
      , COL__SELECT, FALSE _
      , COL_VISIBLE, TRUE _
      , COL____PATH, Fol _
      , COL____NAME, Nam _
      , COL_P_WIDTH, PEEK(UBYTE, def->P) _
      , COL_L_WIDTH, PEEK(UBYTE, def->L) _
      , COL_P_COLOR, def->P[1] _
      , COL_L_COLOR, def->L[1] _
      , COL__LOADER, Loa _
      ,-1)
    VAR s = gtk_tree_model_get_string_from_iter(model, @iter)
    PEEK(TrackLoader, Loa).Path = *s
    g_free(s)
  END IF
  IF Par THEN gtk_tree_iter_free(Par) : EXIT CONSTRUCTOR
  ' expand new folder row
  VAR path = gtk_tree_model_get_path(model, @new_par)
  gtk_tree_view_expand_row(GTK_TREE_VIEW(.TVT), path, FALSE)
  gtk_tree_path_free(path)
END WITH
END CONSTRUCTOR



FUNCTION track_store_remove CDECL( _
    BYVAL Model AS GtkTreeModel PTR _
  , BYVAL Path AS GtkTreePath PTR _
  , BYVAL Iter AS GtkTreeIter PTR _
  , BYVAL UserData AS gpointer) AS gboolean
  DIM AS TrackLoader PTR loa
  DIM AS gchar PTR pcs, lcs, nam, fol
  gtk_tree_model_get(Model, Iter _
    , COL____PATH, @fol _
    , COL____NAME, @nam _
    , COL_P_COLOR, @pcs _
    , COL_L_COLOR, @lcs _
    , COL__LOADER, @loa _
    , -1)
  IF pcs THEN g_free(pcs)
  IF lcs THEN g_free(lcs)
  IF fol THEN g_free(fol)
  IF nam THEN g_free(nam)
  IF loa THEN DELETE(loa)
  RETURN FALSE
END FUNCTION



SUB TS_finalize()
WITH *.GUI
  gtk_tree_model_foreach(GTK_TREE_MODEL(.STO) _
    , @track_store_remove(), NULL)
  gtk_tree_store_clear(GTK_TREE_STORE(.STO))
END WITH
END SUB



SUB TS_remove(BYVAL Child AS GtkTreeIter PTR)
WITH *.GUI
  VAR model = GTK_TREE_MODEL(.STO)
  DIM AS GtkTreeIter parent
  gtk_tree_model_iter_parent(model, @parent, Child)
  track_store_remove(model, NULL, Child, NULL)
  gtk_tree_store_remove(GTK_TREE_STORE(.STO), Child)
  IF FALSE = gtk_tree_model_iter_has_child(model, @parent) _
    THEN gtk_tree_store_remove(GTK_TREE_STORE(.STO), @parent)
END WITH
END SUB



FUNCTION TS_nearest._dist CDECL( _
    BYVAL Model AS GtkTreeModel PTR _
  , BYVAL Path AS GtkTreePath PTR _
  , BYVAL Iter AS GtkTreeIter PTR _
  , BYVAL UserData AS gpointer) AS gboolean
  DIM AS TrackLoader PTR loa
  DIM AS gboolean en
  gtk_tree_model_get(Model, Iter _
    , COL__ENABLE, @en _
    , COL__LOADER, @loa _
    , -1)
  IF FALSE = en ORELSE NULL = loa THEN RETURN FALSE
  WITH PEEK(TS_nearest, UserData)
    VAR d = loa->Nearest(.Lat, .Lon) _
     , d0 = .Res(0).Dist - d, ii = -1L
    FOR i AS LONG = 0 TO UBOUND(.Res)
    WITH .Res(i)
      IF 0 = .Loa THEN .Dist = d : .Loa = loa : RETURN FALSE ' fill empty slot
      IF .Dist <= d THEN CONTINUE FOR
      VAR di = .Dist - d
      IF di < d0 THEN ii = i : d0 = di
    END WITH
    NEXT
    IF ii >= 0 THEN .Res(ii).Dist = d : .Res(ii).Loa = loa
  END WITH
  RETURN FALSE
END FUNCTION



CONSTRUCTOR TS_nearest( _
    BYVAL La AS float _
  , BYVAL Lo AS float)
  Lat = La
  Lon = Lo

  gtk_tree_model_foreach(GTK_TREE_MODEL(GUI->STO) _
    , @TS_nearest._dist(), CAST(gpointer, @THIS))

END CONSTRUCTOR



FUNCTION TS_bbox._bounds CDECL( _
    BYVAL Model AS GtkTreeModel PTR _
  , BYVAL Path AS GtkTreePath PTR _
  , BYVAL Iter AS GtkTreeIter PTR _
  , BYVAL UserData AS gpointer) AS gboolean
  DIM AS TrackLoader PTR loa
  DIM AS gboolean en
  gtk_tree_model_get(Model, Iter _
    , COL__ENABLE, @en _
    , COL__LOADER, @loa _
    , -1)
  IF NULL = loa THEN RETURN FALSE ' folder row

  WITH PEEK(TS_bbox, UserData)
    IF en OR .Mode THEN
      IF .La0 > loa->Mn.Lat THEN .La0 = loa->Mn.Lat
      IF .La1 < loa->Mx.Lat THEN .La1 = loa->Mx.Lat
      IF .Lo0 > loa->Mn.Lon THEN .Lo0 = loa->Mn.Lon
      IF .Lo1 < loa->Mx.Lon THEN .Lo1 = loa->Mx.Lon
      .Cnt += 1
    END IF
  END WITH
  RETURN FALSE
END FUNCTION



CONSTRUCTOR TS_bbox(BYVAL Mo AS gboolean)
  Mode = Mo

  gtk_tree_model_foreach(GTK_TREE_MODEL(GUI->STO) _
    , @TS_bbox._bounds(), CAST(gpointer, @THIS))

  IF Cnt THEN _
    track_layer_set_bbox(TRACK_LAYER(GUI->TRL), La0, La1, Lo0, Lo1)

END CONSTRUCTOR



SUB TS_select(BYVAL Path AS STRING)
  STATIC AS STRING last
  IF 0 = LEN(Path) THEN EXIT SUB
WITH *GUI
  DIM AS GtkTreeIter iter
  VAR store = GTK_TREE_STORE(.STO) _
    , model = GTK_TREE_MODEL(.STO)
  IF LEN(last) THEN
    gtk_tree_model_get_iter_from_string(model, @iter, last)
    gtk_tree_store_set(store, @iter, COL__SELECT, FALSE, -1)
  END IF
  last = Path
  gtk_tree_model_get_iter_from_string(model, @iter, last)
  gtk_tree_store_set(store, @iter, COL__SELECT, TRUE, -1)
  DIM AS TrackLoader PTR loa
  gtk_tree_model_get(model, @iter, COL__LOADER, @loa, -1)

  VAR p = gtk_tree_path_new_from_string(last)
  gtk_tree_view_expand_to_path(GTK_TREE_VIEW(.TVT), p)
  gtk_tree_path_free(p)
  track_layer_set_loader(TRACK_LAYER(.TRL), loa)
END WITH
END SUB




SUB TS_preference(BYVAL Loa AS TrackLoader PTR)
WITH *GUI
  IF NULL = Loa THEN EXIT SUB
  DIM AS gint lw, pw
  DIM AS gchar PTR lc, pc, nam
  DIM AS GtkTreeIter iter
  DIM AS GdkRGBA x
  VAR model = GTK_TREE_MODEL(.STO)

  gtk_tree_model_get_iter_from_string(model, @iter, Loa->Path)
  gtk_tree_model_get(model, @iter _
    , COL____NAME, @nam _
    , COL_P_WIDTH, @pw _
    , COL_L_WIDTH, @lw _
    , COL_P_COLOR, @pc _
    , COL_L_COLOR, @lc _
    , -1)

  IF gdk_rgba_parse(@x, pc) THEN _
    gtk_color_chooser_set_rgba(GTK_COLOR_CHOOSER(.BPC), @x)
  g_free(pc)
  IF gdk_rgba_parse(@x, lc) THEN _
    gtk_color_chooser_set_rgba(GTK_COLOR_CHOOSER(.BLC), @x)
  g_free(lc)
  gtk_adjustment_set_value(GTK_ADJUSTMENT(.APW), (pw AND &b1111) SHL 1)
  gtk_combo_box_set_active( GTK_COMBO_BOX(.CPD), (pw SHR 4) AND &b11)
  gtk_combo_box_set_active( GTK_COMBO_BOX(.CPC), (pw SHR 6) AND &b11)
  gtk_adjustment_set_value(GTK_ADJUSTMENT(.ALW), lw)
  gtk_window_set_title(GTK_WINDOW(.DTP), nam)
  g_free(nam)
WITH *Loa
  gtk_label_set_text(GTK_LABEL(GUI->LTD), .Desc) '?? markup
  gtk_label_set_text(GTK_LABEL(GUI->LTE), _
    .Mn.Lon*Rad2Deg & " to " & .Mx.Lon*Rad2Deg & !"\n" _
  & .Mn.Lat*Rad2Deg & " to " & .Mx.Lat*Rad2Deg & !"\n" _
  & .Mn.Ele & " to " & .Mx.Ele & !"\n" _
  & .Mn.Spd & " to " & .Mx.Spd & !"\n" _
  & .Mn.Ang & " to " & .Mx.Ang _
  )
END WITH

  SELECT CASE AS CONST gtk_dialog_run(GTK_DIALOG(.DTP))
  CASE GTK_RESPONSE_OK
    lw = CAST(gint,  gtk_adjustment_get_value(GTK_ADJUSTMENT(.ALW)))
    pw = CAST(gint,  gtk_adjustment_get_value(GTK_ADJUSTMENT(.APW))) SHR 1 _
       + CAST(gint, *gtk_combo_box_get_active_id(GTK_COMBO_BOX(.CPD))) SHL 4 _
       + CAST(gint, *gtk_combo_box_get_active_id(GTK_COMBO_BOX(.CPC))) SHL 6
    gtk_color_chooser_get_rgba(GTK_COLOR_CHOOSER(.BLC), @x)
    lc = gdk_rgba_to_string(@x)
    gtk_color_chooser_get_rgba(GTK_COLOR_CHOOSER(.BPC), @x)
    pc = gdk_rgba_to_string(@x)
    gtk_tree_store_set(GTK_TREE_STORE(.STO), @iter _
      , COL_P_WIDTH, pw _
      , COL_L_WIDTH, lw _
      , COL_P_COLOR, pc _
      , COL_L_COLOR, lc _
      , -1)
    g_free(pc)
    g_free(lc)
    track_layer_redraw(TRACK_LAYER(.TRL))
  CASE 1
    TS_remove(@iter)
  CASE 2 '!! for testing: center track on map
    track_layer_set_loader(TRACK_LAYER(.TRL), Loa)
  END SELECT
  gtk_widget_hide(GTK_WIDGET(.DTP))
END WITH
END SUB